LXR linux/arch/x86/kernel/vmlinux.lds.S

   1/*
   2 * ld script for the x86 kernel
   3 *
   4 * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   5 *
   6 * Modernisation, unification and other changes and fixes:
   7 *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
   8 *
   9 *
  10 * Don't define absolute symbols until and unless you know that symbol
  11 * value is should remain constant even if kernel image is relocated
  12 * at run time. Absolute symbols are not relocated. If symbol value should
  13 * change if kernel is relocated, make the symbol section relative and
  14 * put it inside the section definition.
  15 */
  16
  17#ifdef CONFIG_X86_32
  18#define LOAD_OFFSET __PAGE_OFFSET
  19#else
  20#define LOAD_OFFSET __START_KERNEL_map
  21#endif
  22
  23#include <asm-generic/vmlinux.lds.h>
  24#include <asm/asm-offsets.h>
  25#include <asm/thread_info.h>
  26#include <asm/page_types.h>
  27#include <asm/cache.h>
  28#include <asm/boot.h>
  29
  30#undef i386     /* in case the preprocessor is a 32bit one */
  31
  32OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
  33
  34#ifdef CONFIG_X86_32
  35OUTPUT_ARCH(i386)
  36ENTRY(phys_startup_32)
  37jiffies = jiffies_64;
  38#else
  39OUTPUT_ARCH(i386:x86-64)
  40ENTRY(phys_startup_64)
  41jiffies_64 = jiffies;
  42#endif
  43
  44#if defined(CONFIG_X86_64) && defined(CONFIG_DEBUG_RODATA)
  45/*
  46 * On 64-bit, align RODATA to 2MB so that even with CONFIG_DEBUG_RODATA
  47 * we retain large page mappings for boundaries spanning kernel text, rodata
  48 * and data sections.
  49 *
  50 * However, kernel identity mappings will have different RWX permissions
  51 * to the pages mapping to text and to the pages padding (which are freed) the
  52 * text section. Hence kernel identity mappings will be broken to smaller
  53 * pages. For 64-bit, kernel text and kernel identity mappings are different,
  54 * so we can enable protection checks that come with CONFIG_DEBUG_RODATA,
  55 * as well as retain 2MB large page mappings for kernel text.
  56 */
  57#define X64_ALIGN_DEBUG_RODATA_BEGIN    . = ALIGN(HPAGE_SIZE);
  58
  59#define X64_ALIGN_DEBUG_RODATA_END                              \
  60                . = ALIGN(HPAGE_SIZE);                          \
  61                __end_rodata_hpage_align = .;
  62
  63#else
  64
  65#define X64_ALIGN_DEBUG_RODATA_BEGIN
  66#define X64_ALIGN_DEBUG_RODATA_END
  67
  68#endif
  69
  70PHDRS {
  71        text PT_LOAD FLAGS(5);          /* R_E */
  72        data PT_LOAD FLAGS(6);          /* RW_ */
  73#ifdef CONFIG_X86_64
  74#ifdef CONFIG_SMP
  75        percpu PT_LOAD FLAGS(6);        /* RW_ */
  76#endif
  77        init PT_LOAD FLAGS(7);          /* RWE */
  78#endif
  79        note PT_NOTE FLAGS(0);          /* ___ */
  80}
  81
  82#ifdef CONFIG_PAGE_TABLE_ISOLATION
  83#define ALIGN_KAISER()  . = ALIGN(PAGE_SIZE);
  84#else
  85#define ALIGN_KAISER()
  86#endif
  87
  88SECTIONS
  89{
  90#ifdef CONFIG_X86_32
  91        . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
  92        phys_startup_32 = startup_32 - LOAD_OFFSET;
  93#else
  94        . = __START_KERNEL;
  95        phys_startup_64 = startup_64 - LOAD_OFFSET;
  96#endif
  97
  98        /* Text and read-only data */
  99        .text :  AT(ADDR(.text) - LOAD_OFFSET) {
 100                _text = .;
 101                _stext = .;
 102                /* bootstrapping code */
 103                HEAD_TEXT
 104                . = ALIGN(8);
 105                TEXT_TEXT
 106                SCHED_TEXT
 107                CPUIDLE_TEXT
 108                LOCK_TEXT
 109                ALIGN_KAISER()
 110                KPROBES_TEXT
 111                ENTRY_TEXT
 112                IRQENTRY_TEXT
 113                ALIGN_KAISER()
 114                *(.fixup)
 115                *(.gnu.warning)
 116                /* End of text section */
 117                _etext = .;
 118        } :text = 0x9090
 119
 120        NOTES :text :note
 121
 122        EXCEPTION_TABLE(16) :text = 0x9090
 123
 124        MC_EXCEPTION_TABLE(16) :text = 0x9090
 125
 126#if defined(CONFIG_DEBUG_RODATA)
 127        /* .text should occupy whole number of pages */
 128        . = ALIGN(PAGE_SIZE);
 129#endif
 130        X64_ALIGN_DEBUG_RODATA_BEGIN
 131        RO_DATA(PAGE_SIZE)
 132        X64_ALIGN_DEBUG_RODATA_END
 133
 134        /* Data */
 135        .data : AT(ADDR(.data) - LOAD_OFFSET) {
 136                /* Start of data section */
 137                _sdata = .;
 138
 139                /* init_task */
 140                INIT_TASK_DATA(THREAD_SIZE)
 141
 142#ifdef CONFIG_X86_32
 143                /* 32 bit has nosave before _edata */
 144                NOSAVE_DATA
 145#endif
 146
 147                PAGE_ALIGNED_DATA(PAGE_SIZE)
 148
 149                CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 150
 151                DATA_DATA
 152                CONSTRUCTORS
 153
 154                /* rarely changed data like cpu maps */
 155                READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
 156
 157                /* End of data section */
 158                _edata = .;
 159        } :data
 160
 161#ifdef CONFIG_X86_64
 162
 163        . = ALIGN(PAGE_SIZE);
 164        __vvar_page = .;
 165
 166        .vvar : AT(ADDR(.vvar) - LOAD_OFFSET) {
 167                /* work around gold bug 13023 */
 168                __vvar_beginning_hack = .;
 169
 170                /* Place all vvars at the offsets in asm/vvar.h. */
 171#define EMIT_VVAR(name, offset)                         \
 172                . = __vvar_beginning_hack + offset;     \
 173                *(.vvar_ ## name)
 174#define __VVAR_KERNEL_LDS
 175#include <asm/vvar.h>
 176#undef __VVAR_KERNEL_LDS
 177#undef EMIT_VVAR
 178
 179        } :data
 180
 181       . = ALIGN(__vvar_page + PAGE_SIZE, PAGE_SIZE);
 182
 183#endif /* CONFIG_X86_64 */
 184
 185        /* Init code and data - will be freed after init */
 186        . = ALIGN(PAGE_SIZE);
 187        .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
 188                __init_begin = .; /* paired with __init_end */
 189        }
 190
 191#if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
 192        /*
 193         * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
 194         * output PHDR, so the next output section - .init.text - should
 195         * start another segment - init.
 196         */
 197        PERCPU_VADDR(INTERNODE_CACHE_BYTES, 0, :percpu)
 198        ASSERT(SIZEOF(.data..percpu) < CONFIG_PHYSICAL_START,
 199               "per-CPU data too large - increase CONFIG_PHYSICAL_START")
 200#endif
 201
 202        INIT_TEXT_SECTION(PAGE_SIZE)
 203#ifdef CONFIG_X86_64
 204        :init
 205#endif
 206
 207        INIT_DATA_SECTION(16)
 208
 209        .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
 210                __x86_cpu_dev_start = .;
 211                *(.x86_cpu_dev.init)
 212                __x86_cpu_dev_end = .;
 213        }
 214
 215        /*
 216         * start address and size of operations which during runtime
 217         * can be patched with virtualization friendly instructions or
 218         * baremetal native ones. Think page table operations.
 219         * Details in paravirt_types.h
 220         */
 221        . = ALIGN(8);
 222        .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
 223                __parainstructions = .;
 224                *(.parainstructions)
 225                __parainstructions_end = .;
 226        }
 227
 228        /*
 229         * struct alt_inst entries. From the header (alternative.h):
 230         * "Alternative instructions for different CPU types or capabilities"
 231         * Think locking instructions on spinlocks.
 232         */
 233        . = ALIGN(8);
 234        .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
 235                __alt_instructions = .;
 236                *(.altinstructions)
 237                __alt_instructions_end = .;
 238        }
 239
 240        /*
 241         * And here are the replacement instructions. The linker sticks
 242         * them as binary blobs. The .altinstructions has enough data to
 243         * get the address and the length of them to patch the kernel safely.
 244         */
 245        .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
 246                *(.altinstr_replacement)
 247        }
 248
 249        /*
 250         * struct iommu_table_entry entries are injected in this section.
 251         * It is an array of IOMMUs which during run time gets sorted depending
 252         * on its dependency order. After rootfs_initcall is complete
 253         * this section can be safely removed.
 254         */
 255        .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
 256                __iommu_table = .;
 257                *(.iommu_table)
 258                __iommu_table_end = .;
 259        }
 260
 261        . = ALIGN(8);
 262        .apicdrivers : AT(ADDR(.apicdrivers) - LOAD_OFFSET) {
 263                __apicdrivers = .;
 264                *(.apicdrivers);
 265                __apicdrivers_end = .;
 266        }
 267
 268        . = ALIGN(8);
 269        /*
 270         * .exit.text is discard at runtime, not link time, to deal with
 271         *  references from .altinstructions and .eh_frame
 272         */
 273        .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
 274                EXIT_TEXT
 275        }
 276
 277        .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
 278                EXIT_DATA
 279        }
 280
 281#if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
 282        PERCPU_SECTION(INTERNODE_CACHE_BYTES)
 283#endif
 284
 285        . = ALIGN(PAGE_SIZE);
 286
 287        /* freed after init ends here */
 288        .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
 289                __init_end = .;
 290        }
 291
 292        /*
 293         * smp_locks might be freed after init
 294         * start/end must be page aligned
 295         */
 296        . = ALIGN(PAGE_SIZE);
 297        .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
 298                __smp_locks = .;
 299                *(.smp_locks)
 300                . = ALIGN(PAGE_SIZE);
 301                __smp_locks_end = .;
 302        }
 303
 304#ifdef CONFIG_X86_64
 305        .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
 306                NOSAVE_DATA
 307        }
 308#endif
 309
 310        /* BSS */
 311        . = ALIGN(PAGE_SIZE);
 312        .bss : AT(ADDR(.bss) - LOAD_OFFSET) {
 313                __bss_start = .;
 314                *(.bss..page_aligned)
 315                *(.bss)
 316                . = ALIGN(PAGE_SIZE);
 317                __bss_stop = .;
 318        }
 319
 320        /*
 321         * The memory occupied from _text to here, __end_of_kernel_reserve, is
 322         * automatically reserved in setup_arch(). Anything after here must be
 323         * explicitly reserved using memblock_reserve() or it will be discarded
 324         * and treated as available memory.
 325         */
 326        __end_of_kernel_reserve = .;
 327
 328        . = ALIGN(PAGE_SIZE);
 329        .brk : AT(ADDR(.brk) - LOAD_OFFSET) {
 330                __brk_base = .;
 331                . += 64 * 1024;         /* 64k alignment slop space */
 332                *(.brk_reservation)     /* areas brk users have reserved */
 333                __brk_limit = .;
 334        }
 335
 336        . = ALIGN(PAGE_SIZE);           /* keep VO_INIT_SIZE page aligned */
 337        _end = .;
 338
 339#ifdef CONFIG_AMD_MEM_ENCRYPT
 340        /*
 341         * SME workarea section: Lives outside of the kernel proper (_text -
 342         * _end) for performing in-place encryption of the kernel during boot.
 343         *
 344         * Resides after _end because even though the .brk section is after
 345         * __end_of_kernel_reserve, the .brk section is later reserved as a
 346         * part of the kernel. It is used in very early boot code and not
 347         * needed after that, so it is located after __end_of_kernel_reserve
 348         * so that it will be discarded and become part of the available
 349         * memory.
 350         *
 351         * Resides on a 2MB boundary to simplify the pagetable setup used for
 352         * the encryption.
 353         */
 354        . = ALIGN(HPAGE_SIZE);
 355        .sme : AT(ADDR(.sme) - LOAD_OFFSET) {
 356                __sme_begin = .;
 357                *(.sme)
 358                . = ALIGN(HPAGE_SIZE);
 359                __sme_end = .;
 360        }
 361#endif
 362
 363        STABS_DEBUG
 364        DWARF_DEBUG
 365
 366        DISCARDS
 367        /DISCARD/ : {
 368                *(.eh_frame)
 369                *(__func_stack_frame_non_standard)
 370        }
 371}
 372
 373
 374#ifdef CONFIG_X86_32
 375/*
 376 * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
 377 */
 378. = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
 379           "kernel image bigger than KERNEL_IMAGE_SIZE");
 380#else
 381/*
 382 * Per-cpu symbols which need to be offset from __per_cpu_load
 383 * for the boot processor.
 384 */
 385#define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
 386INIT_PER_CPU(gdt_page);
 387INIT_PER_CPU(irq_stack_union);
 388
 389/*
 390 * Build-time check on the image size:
 391 */
 392. = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
 393           "kernel image bigger than KERNEL_IMAGE_SIZE");
 394
 395#ifdef CONFIG_SMP
 396. = ASSERT((irq_stack_union == 0),
 397           "irq_stack_union is not at start of per-cpu area");
 398#endif
 399
 400#endif /* CONFIG_X86_32 */
 401
 402#ifdef CONFIG_KEXEC_CORE
 403#include <asm/kexec.h>
 404
 405. = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
 406           "kexec control code size is too big");
 407#endif
 408
 409