LXR linux/arch/um/kernel/dyn.lds.S

   1#include <asm-generic/vmlinux.lds.h>
   2#include <asm/page.h>
   3
   4OUTPUT_FORMAT(ELF_FORMAT)
   5OUTPUT_ARCH(ELF_ARCH)
   6ENTRY(_start)
   7jiffies = jiffies_64;
   8
   9SECTIONS
  10{
  11  PROVIDE (__executable_start = START);
  12  . = START + SIZEOF_HEADERS;
  13  .interp         : { *(.interp) }
  14  __binary_start = .;
  15  . = ALIGN(4096);              /* Init code and data */
  16  _text = .;
  17  _stext = .;
  18  __init_begin = .;
  19  INIT_TEXT_SECTION(PAGE_SIZE)
  20
  21  . = ALIGN(PAGE_SIZE);
  22
  23  /* Read-only sections, merged into text segment: */
  24  .hash           : { *(.hash) }
  25  .gnu.hash       : { *(.gnu.hash) }
  26  .dynsym         : { *(.dynsym) }
  27  .dynstr         : { *(.dynstr) }
  28  .gnu.version    : { *(.gnu.version) }
  29  .gnu.version_d  : { *(.gnu.version_d) }
  30  .gnu.version_r  : { *(.gnu.version_r) }
  31  .rel.init       : { *(.rel.init) }
  32  .rela.init      : { *(.rela.init) }
  33  .rel.text       : { *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*) }
  34  .rela.text      : { *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*) }
  35  .rel.fini       : { *(.rel.fini) }
  36  .rela.fini      : { *(.rela.fini) }
  37  .rel.rodata     : { *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*) }
  38  .rela.rodata    : { *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*) }
  39  .rel.data       : { *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*) }
  40  .rela.data      : { *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*) }
  41  .rel.tdata      : { *(.rel.tdata .rel.tdata.* .rel.gnu.linkonce.td.*) }
  42  .rela.tdata     : { *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*) }
  43  .rel.tbss       : { *(.rel.tbss .rel.tbss.* .rel.gnu.linkonce.tb.*) }
  44  .rela.tbss      : { *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*) }
  45  .rel.ctors      : { *(.rel.ctors) }
  46  .rela.ctors     : { *(.rela.ctors) }
  47  .rel.dtors      : { *(.rel.dtors) }
  48  .rela.dtors     : { *(.rela.dtors) }
  49  .rel.got        : { *(.rel.got) }
  50  .rela.got       : { *(.rela.got) }
  51  .rel.bss        : { *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*) }
  52  .rela.bss       : { *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*) }
  53  .rel.plt        : { *(.rel.plt) }
  54  .rela.plt       : { *(.rela.plt) }
  55  .init           : {
  56    KEEP (*(.init))
  57  } =0x90909090
  58  .plt            : { *(.plt) }
  59  .text           : {
  60    TEXT_TEXT
  61    SCHED_TEXT
  62    LOCK_TEXT
  63    *(.fixup)
  64    *(.stub .text.* .gnu.linkonce.t.*)
  65    /* .gnu.warning sections are handled specially by elf32.em.  */
  66    *(.gnu.warning)
  67
  68    . = ALIGN(PAGE_SIZE);
  69  } =0x90909090
  70  . = ALIGN(PAGE_SIZE);
  71  .syscall_stub : {
  72        __syscall_stub_start = .;
  73        *(.__syscall_stub*)
  74        __syscall_stub_end = .;
  75  }
  76  .fini           : {
  77    KEEP (*(.fini))
  78  } =0x90909090
  79
  80  .kstrtab : { *(.kstrtab) }
  81
  82  #include "asm/common.lds.S"
  83
  84  init.data : { INIT_DATA }
  85
  86  /* Ensure the __preinit_array_start label is properly aligned.  We
  87     could instead move the label definition inside the section, but
  88     the linker would then create the section even if it turns out to
  89     be empty, which isn't pretty.  */
  90  . = ALIGN(32 / 8);
  91  .preinit_array     : { *(.preinit_array) }
  92  .init_array     : { *(.init_array) }
  93  .fini_array     : { *(.fini_array) }
  94  .data           : {
  95    INIT_TASK_DATA(KERNEL_STACK_SIZE)
  96    . = ALIGN(KERNEL_STACK_SIZE);
  97    *(.data.init_irqstack)
  98    DATA_DATA
  99    *(.data.* .gnu.linkonce.d.*)
 100    SORT(CONSTRUCTORS)
 101  }
 102  .data1          : { *(.data1) }
 103  .tdata          : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
 104  .tbss           : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
 105  .eh_frame       : { KEEP (*(.eh_frame)) }
 106  .gcc_except_table   : { *(.gcc_except_table) }
 107  .dynamic        : { *(.dynamic) }
 108  .ctors          : {
 109    /* gcc uses crtbegin.o to find the start of
 110       the constructors, so we make sure it is
 111       first.  Because this is a wildcard, it
 112       doesn't matter if the user does not
 113       actually link against crtbegin.o; the
 114       linker won't look for a file to match a
 115       wildcard.  The wildcard also means that it
 116       doesn't matter which directory crtbegin.o
 117       is in.  */
 118    KEEP (*crtbegin.o(.ctors))
 119    /* We don't want to include the .ctor section from
 120       from the crtend.o file until after the sorted ctors.
 121       The .ctor section from the crtend file contains the
 122       end of ctors marker and it must be last */
 123    KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
 124    KEEP (*(SORT(.ctors.*)))
 125    KEEP (*(.ctors))
 126  }
 127  .dtors          : {
 128    KEEP (*crtbegin.o(.dtors))
 129    KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
 130    KEEP (*(SORT(.dtors.*)))
 131    KEEP (*(.dtors))
 132  }
 133  .jcr            : { KEEP (*(.jcr)) }
 134  .got            : { *(.got.plt) *(.got) }
 135  _edata = .;
 136  PROVIDE (edata = .);
 137  .bss            : {
 138   __bss_start = .;
 139   *(.dynbss)
 140   *(.bss .bss.* .gnu.linkonce.b.*)
 141   *(COMMON)
 142   /* Align here to ensure that the .bss section occupies space up to
 143      _end.  Align after .bss to ensure correct alignment even if the
 144      .bss section disappears because there are no input sections.  */
 145   . = ALIGN(32 / 8);
 146  . = ALIGN(32 / 8);
 147  }
 148  _end = .;
 149  PROVIDE (end = .);
 150
 151  STABS_DEBUG
 152
 153  DWARF_DEBUG
 154
 155  DISCARDS
 156}
 157