LXR linux/arch/um/kernel/uml.lds.S

   1#include <asm-generic/vmlinux.lds.h>
   2#include <asm/page.h>
   3
   4OUTPUT_FORMAT(ELF_FORMAT)
   5OUTPUT_ARCH(ELF_ARCH)
   6ENTRY(_start)
   7jiffies = jiffies_64;
   8
   9SECTIONS
  10{
  11  /* This must contain the right address - not quite the default ELF one.*/
  12  PROVIDE (__executable_start = START);
  13  /* Static binaries stick stuff here, like the sigreturn trampoline,
  14   * invisibly to objdump.  So, just make __binary_start equal to the very
  15   * beginning of the executable, and if there are unmapped pages after this,
  16   * they are forever unusable.
  17   */
  18  __binary_start = START;
  19
  20  . = START + SIZEOF_HEADERS;
  21
  22  _text = .;
  23  _stext = .;
  24  __init_begin = .;
  25  INIT_TEXT_SECTION(PAGE_SIZE)
  26  . = ALIGN(PAGE_SIZE);
  27
  28  .text      :
  29  {
  30    TEXT_TEXT
  31    SCHED_TEXT
  32    LOCK_TEXT
  33    *(.fixup)
  34    /* .gnu.warning sections are handled specially by elf32.em.  */
  35    *(.gnu.warning)
  36    *(.gnu.linkonce.t*)
  37  }
  38
  39  . = ALIGN(PAGE_SIZE);
  40  .syscall_stub : {
  41        __syscall_stub_start = .;
  42        *(.__syscall_stub*)
  43        __syscall_stub_end = .;
  44  }
  45
  46  #include "asm/common.lds.S"
  47
  48  init.data : { INIT_DATA }
  49  .data    :
  50  {
  51    INIT_TASK_DATA(KERNEL_STACK_SIZE)
  52    . = ALIGN(KERNEL_STACK_SIZE);
  53    *(.data.init_irqstack)
  54    DATA_DATA
  55    *(.gnu.linkonce.d*)
  56    CONSTRUCTORS
  57  }
  58  .data1   : { *(.data1) }
  59  .ctors         :
  60  {
  61    *(.ctors)
  62  }
  63  .dtors         :
  64  {
  65    *(.dtors)
  66  }
  67
  68  .got           : { *(.got.plt) *(.got) }
  69  .dynamic       : { *(.dynamic) }
  70  .tdata          : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
  71  .tbss           : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
  72  /* We want the small data sections together, so single-instruction offsets
  73     can access them all, and initialized data all before uninitialized, so
  74     we can shorten the on-disk segment size.  */
  75  .sdata     : { *(.sdata) }
  76  _edata  =  .;
  77  PROVIDE (edata = .);
  78  . = ALIGN(PAGE_SIZE);
  79  __bss_start = .;
  80  PROVIDE(_bss_start = .);
  81  SBSS(0)
  82  BSS(0)
  83  _end = .;
  84  PROVIDE (end = .);
  85
  86  STABS_DEBUG
  87
  88  DWARF_DEBUG
  89
  90  DISCARDS
  91}
  92