LXR linux/arch/microblaze/kernel/vmlinux.lds.S

   1/*
   2 * Copyright (C) 2008-2009 Michal Simek <monstr@monstr.eu>
   3 * Copyright (C) 2008-2009 PetaLogix
   4 * Copyright (C) 2006 Atmark Techno, Inc.
   5 *
   6 * This file is subject to the terms and conditions of the GNU General Public
   7 * License. See the file "COPYING" in the main directory of this archive
   8 * for more details.
   9 */
  10
  11OUTPUT_ARCH(microblaze)
  12ENTRY(microblaze_start)
  13
  14#include <asm/page.h>
  15#include <asm-generic/vmlinux.lds.h>
  16#include <asm/thread_info.h>
  17
  18#ifdef __MICROBLAZEEL__
  19jiffies = jiffies_64;
  20#else
  21jiffies = jiffies_64 + 4;
  22#endif
  23
  24SECTIONS {
  25        . = CONFIG_KERNEL_START;
  26        microblaze_start = CONFIG_KERNEL_BASE_ADDR;
  27        .text : AT(ADDR(.text) - LOAD_OFFSET) {
  28                _text = . ;
  29                _stext = . ;
  30                HEAD_TEXT
  31                TEXT_TEXT
  32                *(.fixup)
  33                EXIT_TEXT
  34                EXIT_CALL
  35                SCHED_TEXT
  36                LOCK_TEXT
  37                KPROBES_TEXT
  38                IRQENTRY_TEXT
  39                . = ALIGN (4) ;
  40                _etext = . ;
  41        }
  42
  43        . = ALIGN (4) ;
  44        __fdt_blob : AT(ADDR(__fdt_blob) - LOAD_OFFSET) {
  45                _fdt_start = . ;                /* place for fdt blob */
  46                *(__fdt_blob) ;                 /* Any link-placed DTB */
  47                . = _fdt_start + 0x8000;        /* Pad up to 32kbyte */
  48                _fdt_end = . ;
  49        }
  50
  51        . = ALIGN(16);
  52        RODATA
  53        EXCEPTION_TABLE(16)
  54
  55        /*
  56         * sdata2 section can go anywhere, but must be word aligned
  57         * and SDA2_BASE must point to the middle of it
  58         */
  59        .sdata2 : AT(ADDR(.sdata2) - LOAD_OFFSET) {
  60                _ssrw = .;
  61                . = ALIGN(PAGE_SIZE); /* page aligned when MMU used */
  62                *(.sdata2)
  63        . = ALIGN(8);
  64        _essrw = .;
  65        _ssrw_size = _essrw - _ssrw;
  66        _KERNEL_SDA2_BASE_ = _ssrw + (_ssrw_size / 2);
  67        }
  68
  69        _sdata = . ;
  70        RW_DATA_SECTION(32, PAGE_SIZE, THREAD_SIZE)
  71        _edata = . ;
  72
  73        /* Under the microblaze ABI, .sdata and .sbss must be contiguous */
  74        . = ALIGN(8);
  75        .sdata : AT(ADDR(.sdata) - LOAD_OFFSET) {
  76                _ssro = .;
  77                *(.sdata)
  78        }
  79
  80        .sbss : AT(ADDR(.sbss) - LOAD_OFFSET) {
  81                _ssbss = .;
  82                *(.sbss)
  83                _esbss = .;
  84                _essro = .;
  85                _ssro_size = _essro - _ssro ;
  86                _KERNEL_SDA_BASE_ = _ssro + (_ssro_size / 2) ;
  87        }
  88
  89        . = ALIGN(PAGE_SIZE);
  90        __init_begin = .;
  91
  92        INIT_TEXT_SECTION(PAGE_SIZE)
  93
  94        .init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
  95                INIT_DATA
  96        }
  97
  98        . = ALIGN(4);
  99        .init.ivt : AT(ADDR(.init.ivt) - LOAD_OFFSET) {
 100                __ivt_start = .;
 101                *(.init.ivt)
 102                __ivt_end = .;
 103        }
 104
 105        .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
 106                INIT_SETUP(0)
 107        }
 108
 109        .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET ) {
 110                INIT_CALLS
 111        }
 112
 113        .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
 114                CON_INITCALL
 115        }
 116
 117        SECURITY_INIT
 118
 119        __init_end_before_initramfs = .;
 120
 121        .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
 122                INIT_RAM_FS
 123        }
 124
 125        __init_end = .;
 126
 127        .bss ALIGN (PAGE_SIZE) : AT(ADDR(.bss) - LOAD_OFFSET) {
 128                /* page aligned when MMU used */
 129                __bss_start = . ;
 130                        *(.bss*)
 131                        *(COMMON)
 132                . = ALIGN (4) ;
 133                __bss_stop = . ;
 134        }
 135        . = ALIGN(PAGE_SIZE);
 136        _end = .;
 137
 138        DISCARDS
 139}
 140