LXR linux/scripts/recordmcount.pl

   1#!/usr/bin/perl -w
   2# (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3# Licensed under the terms of the GNU GPL License version 2
   4#
   5# recordmcount.pl - makes a section called __mcount_loc that holds
   6#                   all the offsets to the calls to mcount.
   7#
   8#
   9# What we want to end up with this is that each object file will have a
  10# section called __mcount_loc that will hold the list of pointers to mcount
  11# callers. After final linking, the vmlinux will have within .init.data the
  12# list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13# Later on boot up, the kernel will read this list, save the locations and turn
  14# them into nops. When tracing or profiling is later enabled, these locations
  15# will then be converted back to pointers to some function.
  16#
  17# This is no easy feat. This script is called just after the original
  18# object is compiled and before it is linked.
  19#
  20# When parse this object file using 'objdump', the references to the call
  21# sites are offsets from the section that the call site is in. Hence, all
  22# functions in a section that has a call site to mcount, will have the
  23# offset from the beginning of the section and not the beginning of the
  24# function.
  25#
  26# But where this section will reside finally in vmlinx is undetermined at
  27# this point. So we can't use this kind of offsets to record the final
  28# address of this call site.
  29#
  30# The trick is to change the call offset referring the start of a section to
  31# referring a function symbol in this section. During the link step, 'ld' will
  32# compute the final address according to the information we record.
  33#
  34# e.g.
  35#
  36#  .section ".sched.text", "ax"
  37#        [...]
  38#  func1:
  39#        [...]
  40#        call mcount  (offset: 0x10)
  41#        [...]
  42#        ret
  43#  .globl fun2
  44#  func2:             (offset: 0x20)
  45#        [...]
  46#        [...]
  47#        ret
  48#  func3:
  49#        [...]
  50#        call mcount (offset: 0x30)
  51#        [...]
  52#
  53# Both relocation offsets for the mcounts in the above example will be
  54# offset from .sched.text. If we choose global symbol func2 as a reference and
  55# make another file called tmp.s with the new offsets:
  56#
  57#  .section __mcount_loc
  58#  .quad  func2 - 0x10
  59#  .quad  func2 + 0x10
  60#
  61# We can then compile this tmp.s into tmp.o, and link it back to the original
  62# object.
  63#
  64# In our algorithm, we will choose the first global function we meet in this
  65# section as the reference. But this gets hard if there is no global functions
  66# in this section. In such a case we have to select a local one. E.g. func1:
  67#
  68#  .section ".sched.text", "ax"
  69#  func1:
  70#        [...]
  71#        call mcount  (offset: 0x10)
  72#        [...]
  73#        ret
  74#  func2:
  75#        [...]
  76#        call mcount (offset: 0x20)
  77#        [...]
  78#  .section "other.section"
  79#
  80# If we make the tmp.s the same as above, when we link together with
  81# the original object, we will end up with two symbols for func1:
  82# one local, one global.  After final compile, we will end up with
  83# an undefined reference to func1 or a wrong reference to another global
  84# func1 in other files.
  85#
  86# Since local objects can reference local variables, we need to find
  87# a way to make tmp.o reference the local objects of the original object
  88# file after it is linked together. To do this, we convert func1
  89# into a global symbol before linking tmp.o. Then after we link tmp.o
  90# we will only have a single symbol for func1 that is global.
  91# We can convert func1 back into a local symbol and we are done.
  92#
  93# Here are the steps we take:
  94#
  95# 1) Record all the local and weak symbols by using 'nm'
  96# 2) Use objdump to find all the call site offsets and sections for
  97#    mcount.
  98# 3) Compile the list into its own object.
  99# 4) Do we have to deal with local functions? If not, go to step 8.
 100# 5) Make an object that converts these local functions to global symbols
 101#    with objcopy.
 102# 6) Link together this new object with the list object.
 103# 7) Convert the local functions back to local symbols and rename
 104#    the result as the original object.
 105# 8) Link the object with the list object.
 106# 9) Move the result back to the original object.
 107#
 108
 109use strict;
 110
 111my $P = $0;
 112$P =~ s@.*/@@g;
 113
 114my $V = '0.1';
 115
 116if ($#ARGV != 11) {
 117        print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 118        print "version: $V\n";
 119        exit(1);
 120}
 121
 122my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
 123    $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 124
 125# This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 126if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 127    exit(0);
 128}
 129
 130# Acceptable sections to record.
 131my %text_sections = (
 132     ".text" => 1,
 133     ".ref.text" => 1,
 134     ".sched.text" => 1,
 135     ".spinlock.text" => 1,
 136     ".irqentry.text" => 1,
 137     ".kprobes.text" => 1,
 138     ".text.unlikely" => 1,
 139);
 140
 141# Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
 142$objdump = 'objdump' if (!$objdump);
 143$objcopy = 'objcopy' if (!$objcopy);
 144$cc = 'gcc' if (!$cc);
 145$ld = 'ld' if (!$ld);
 146$nm = 'nm' if (!$nm);
 147$rm = 'rm' if (!$rm);
 148$mv = 'mv' if (!$mv);
 149
 150#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 151#    "'$nm' '$rm' '$mv' '$inputfile'\n";
 152
 153my %locals;             # List of local (static) functions
 154my %weak;               # List of weak functions
 155my %convert;            # List of local functions used that needs conversion
 156
 157my $type;
 158my $local_regex;        # Match a local function (return function)
 159my $weak_regex;         # Match a weak function (return function)
 160my $section_regex;      # Find the start of a section
 161my $function_regex;     # Find the name of a function
 162                        #    (return offset and func name)
 163my $mcount_regex;       # Find the call site to mcount (return offset)
 164my $mcount_adjust;      # Address adjustment to mcount offset
 165my $alignment;          # The .align value to use for $mcount_section
 166my $section_type;       # Section header plus possible alignment command
 167my $can_use_local = 0;  # If we can use local function references
 168
 169# Shut up recordmcount if user has older objcopy
 170my $quiet_recordmcount = ".tmp_quiet_recordmcount";
 171my $print_warning = 1;
 172$print_warning = 0 if ( -f $quiet_recordmcount);
 173
 174##
 175# check_objcopy - whether objcopy supports --globalize-symbols
 176#
 177#  --globalize-symbols came out in 2.17, we must test the version
 178#  of objcopy, and if it is less than 2.17, then we can not
 179#  record local functions.
 180sub check_objcopy
 181{
 182    open (IN, "$objcopy --version |") or die "error running $objcopy";
 183    while (<IN>) {
 184        if (/objcopy.*\s(\d+)\.(\d+)/) {
 185            $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
 186            last;
 187        }
 188    }
 189    close (IN);
 190
 191    if (!$can_use_local && $print_warning) {
 192        print STDERR "WARNING: could not find objcopy version or version " .
 193            "is less than 2.17.\n" .
 194            "\tLocal function references are disabled.\n";
 195        open (QUIET, ">$quiet_recordmcount");
 196        printf QUIET "Disables the warning from recordmcount.pl\n";
 197        close QUIET;
 198    }
 199}
 200
 201if ($arch =~ /(x86(_64)?)|(i386)/) {
 202    if ($bits == 64) {
 203        $arch = "x86_64";
 204    } else {
 205        $arch = "i386";
 206    }
 207}
 208
 209#
 210# We base the defaults off of i386, the other archs may
 211# feel free to change them in the below if statements.
 212#
 213$local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 214$weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 215$section_regex = "Disassembly of section\\s+(\\S+):";
 216$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 217$mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
 218$section_type = '@progbits';
 219$mcount_adjust = 0;
 220$type = ".long";
 221
 222if ($arch eq "x86_64") {
 223    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
 224    $type = ".quad";
 225    $alignment = 8;
 226    $mcount_adjust = -1;
 227
 228    # force flags for this arch
 229    $ld .= " -m elf_x86_64";
 230    $objdump .= " -M x86-64";
 231    $objcopy .= " -O elf64-x86-64";
 232    $cc .= " -m64";
 233
 234} elsif ($arch eq "i386") {
 235    $alignment = 4;
 236    $mcount_adjust = -1;
 237
 238    # force flags for this arch
 239    $ld .= " -m elf_i386";
 240    $objdump .= " -M i386";
 241    $objcopy .= " -O elf32-i386";
 242    $cc .= " -m32";
 243
 244} elsif ($arch eq "s390" && $bits == 32) {
 245    $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_32\\s+_mcount\$";
 246    $mcount_adjust = -4;
 247    $alignment = 4;
 248    $ld .= " -m elf_s390";
 249    $cc .= " -m31";
 250
 251} elsif ($arch eq "s390" && $bits == 64) {
 252    $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
 253    $mcount_adjust = -8;
 254    $alignment = 8;
 255    $type = ".quad";
 256    $ld .= " -m elf64_s390";
 257    $cc .= " -m64";
 258
 259} elsif ($arch eq "sh") {
 260    $alignment = 2;
 261
 262    # force flags for this arch
 263    $ld .= " -m shlelf_linux";
 264    $objcopy .= " -O elf32-sh-linux";
 265    $cc .= " -m32";
 266
 267} elsif ($arch eq "powerpc") {
 268    $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 269    $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
 270    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 271
 272    if ($bits == 64) {
 273        $type = ".quad";
 274    }
 275
 276} elsif ($arch eq "arm") {
 277    $alignment = 2;
 278    $section_type = '%progbits';
 279    $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
 280                        "\\s+(__gnu_mcount_nc|mcount)\$";
 281
 282} elsif ($arch eq "ia64") {
 283    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 284    $type = "data8";
 285
 286    if ($is_module eq "0") {
 287        $cc .= " -mconstant-gp";
 288    }
 289} elsif ($arch eq "sparc64") {
 290    # In the objdump output there are giblets like:
 291    # 0000000000000000 <igmp_net_exit-0x18>:
 292    # As there's some data blobs that get emitted into the
 293    # text section before the first instructions and the first
 294    # real symbols.  We don't want to match that, so to combat
 295    # this we use '\w' so we'll match just plain symbol names,
 296    # and not those that also include hex offsets inside of the
 297    # '<>' brackets.  Actually the generic function_regex setting
 298    # could safely use this too.
 299    $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 300
 301    # Sparc64 calls '_mcount' instead of plain 'mcount'.
 302    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 303
 304    $alignment = 8;
 305    $type = ".xword";
 306    $ld .= " -m elf64_sparc";
 307    $cc .= " -m64";
 308    $objcopy .= " -O elf64-sparc";
 309} elsif ($arch eq "mips") {
 310    # To enable module support, we need to enable the -mlong-calls option
 311    # of gcc for module, after using this option, we can not get the real
 312    # offset of the calling to _mcount, but the offset of the lui
 313    # instruction or the addiu one. herein, we record the address of the
 314    # first one, and then we can replace this instruction by a branch
 315    # instruction to jump over the profiling function to filter the
 316    # indicated functions, or swith back to the lui instruction to trace
 317    # them, which means dynamic tracing.
 318    #
 319    #       c:  3c030000        lui     v1,0x0
 320    #                   c: R_MIPS_HI16  _mcount
 321    #                   c: R_MIPS_NONE  *ABS*
 322    #                   c: R_MIPS_NONE  *ABS*
 323    #      10:  64630000        daddiu  v1,v1,0
 324    #                   10: R_MIPS_LO16 _mcount
 325    #                   10: R_MIPS_NONE *ABS*
 326    #                   10: R_MIPS_NONE *ABS*
 327    #      14:  03e0082d        move    at,ra
 328    #      18:  0060f809        jalr    v1
 329    #
 330    # for the kernel:
 331    #
 332    #     10:   03e0082d        move    at,ra
 333    #     14:   0c000000        jal     0 <loongson_halt>
 334    #                    14: R_MIPS_26   _mcount
 335    #                    14: R_MIPS_NONE *ABS*
 336    #                    14: R_MIPS_NONE *ABS*
 337    #    18:   00020021        nop
 338    if ($is_module eq "0") {
 339            $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
 340    } else {
 341            $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
 342    }
 343    $objdump .= " -Melf-trad".$endian."mips ";
 344
 345    if ($endian eq "big") {
 346            $endian = " -EB ";
 347            $ld .= " -melf".$bits."btsmip";
 348    } else {
 349            $endian = " -EL ";
 350            $ld .= " -melf".$bits."ltsmip";
 351    }
 352
 353    $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
 354    $ld .= $endian;
 355
 356    if ($bits == 64) {
 357            $function_regex =
 358                "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
 359            $type = ".dword";
 360    }
 361} elsif ($arch eq "microblaze") {
 362    # Microblaze calls '_mcount' instead of plain 'mcount'.
 363    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 364} elsif ($arch eq "blackfin") {
 365    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 366    $mcount_adjust = -4;
 367} else {
 368    die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 369}
 370
 371my $text_found = 0;
 372my $read_function = 0;
 373my $opened = 0;
 374my $mcount_section = "__mcount_loc";
 375
 376my $dirname;
 377my $filename;
 378my $prefix;
 379my $ext;
 380
 381if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 382    $dirname = $1;
 383    $filename = $2;
 384} else {
 385    $dirname = ".";
 386    $filename = $inputfile;
 387}
 388
 389if ($filename =~ m,^(.*)(\.\S),) {
 390    $prefix = $1;
 391    $ext = $2;
 392} else {
 393    $prefix = $filename;
 394    $ext = "";
 395}
 396
 397my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 398my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 399
 400check_objcopy();
 401
 402#
 403# Step 1: find all the local (static functions) and weak symbols.
 404#         't' is local, 'w/W' is weak
 405#
 406open (IN, "$nm $inputfile|") || die "error running $nm";
 407while (<IN>) {
 408    if (/$local_regex/) {
 409        $locals{$1} = 1;
 410    } elsif (/$weak_regex/) {
 411        $weak{$2} = $1;
 412    }
 413}
 414close(IN);
 415
 416my @offsets;            # Array of offsets of mcount callers
 417my $ref_func;           # reference function to use for offsets
 418my $offset = 0;         # offset of ref_func to section beginning
 419
 420##
 421# update_funcs - print out the current mcount callers
 422#
 423#  Go through the list of offsets to callers and write them to
 424#  the output file in a format that can be read by an assembler.
 425#
 426sub update_funcs
 427{
 428    return unless ($ref_func and @offsets);
 429
 430    # Sanity check on weak function. A weak function may be overwritten by
 431    # another function of the same name, making all these offsets incorrect.
 432    if (defined $weak{$ref_func}) {
 433        die "$inputfile: ERROR: referencing weak function" .
 434            " $ref_func for mcount\n";
 435    }
 436
 437    # is this function static? If so, note this fact.
 438    if (defined $locals{$ref_func}) {
 439
 440        # only use locals if objcopy supports globalize-symbols
 441        if (!$can_use_local) {
 442            return;
 443        }
 444        $convert{$ref_func} = 1;
 445    }
 446
 447    # Loop through all the mcount caller offsets and print a reference
 448    # to the caller based from the ref_func.
 449    if (!$opened) {
 450        open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 451        $opened = 1;
 452        print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 453        print FILE "\t.align $alignment\n" if (defined($alignment));
 454    }
 455    foreach my $cur_offset (@offsets) {
 456        printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
 457    }
 458}
 459
 460#
 461# Step 2: find the sections and mcount call sites
 462#
 463open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
 464
 465my $text;
 466
 467
 468# read headers first
 469my $read_headers = 1;
 470
 471while (<IN>) {
 472
 473    if ($read_headers && /$mcount_section/) {
 474        #
 475        # Somehow the make process can execute this script on an
 476        # object twice. If it does, we would duplicate the mcount
 477        # section and it will cause the function tracer self test
 478        # to fail. Check if the mcount section exists, and if it does,
 479        # warn and exit.
 480        #
 481        print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 482            "\tThis may be an indication that your build is corrupted.\n" .
 483            "\tDelete $inputfile and try again. If the same object file\n" .
 484            "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 485        exit(-1);
 486    }
 487
 488    # is it a section?
 489    if (/$section_regex/) {
 490        $read_headers = 0;
 491
 492        # Only record text sections that we know are safe
 493        $read_function = defined($text_sections{$1});
 494        # print out any recorded offsets
 495        update_funcs();
 496
 497        # reset all markers and arrays
 498        $text_found = 0;
 499        undef($ref_func);
 500        undef(@offsets);
 501
 502    # section found, now is this a start of a function?
 503    } elsif ($read_function && /$function_regex/) {
 504        $text_found = 1;
 505        $text = $2;
 506
 507        # if this is either a local function or a weak function
 508        # keep looking for functions that are global that
 509        # we can use safely.
 510        if (!defined($locals{$text}) && !defined($weak{$text})) {
 511            $ref_func = $text;
 512            $read_function = 0;
 513            $offset = hex $1;
 514        } else {
 515            # if we already have a function, and this is weak, skip it
 516            if (!defined($ref_func) && !defined($weak{$text}) &&
 517                 # PPC64 can have symbols that start with .L and
 518                 # gcc considers these special. Don't use them!
 519                 $text !~ /^\.L/) {
 520                $ref_func = $text;
 521                $offset = hex $1;
 522            }
 523        }
 524    }
 525    # is this a call site to mcount? If so, record it to print later
 526    if ($text_found && /$mcount_regex/) {
 527        push(@offsets, (hex $1) + $mcount_adjust);
 528    }
 529}
 530
 531# dump out anymore offsets that may have been found
 532update_funcs();
 533
 534# If we did not find any mcount callers, we are done (do nothing).
 535if (!$opened) {
 536    exit(0);
 537}
 538
 539close(FILE);
 540
 541#
 542# Step 3: Compile the file that holds the list of call sites to mcount.
 543#
 544`$cc -o $mcount_o -c $mcount_s`;
 545
 546my @converts = keys %convert;
 547
 548#
 549# Step 4: Do we have sections that started with local functions?
 550#
 551if ($#converts >= 0) {
 552    my $globallist = "";
 553    my $locallist = "";
 554
 555    foreach my $con (@converts) {
 556        $globallist .= " --globalize-symbol $con";
 557        $locallist .= " --localize-symbol $con";
 558    }
 559
 560    my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 561    my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 562
 563    #
 564    # Step 5: set up each local function as a global
 565    #
 566    `$objcopy $globallist $inputfile $globalobj`;
 567
 568    #
 569    # Step 6: Link the global version to our list.
 570    #
 571    `$ld -r $globalobj $mcount_o -o $globalmix`;
 572
 573    #
 574    # Step 7: Convert the local functions back into local symbols
 575    #
 576    `$objcopy $locallist $globalmix $inputfile`;
 577
 578    # Remove the temp files
 579    `$rm $globalobj $globalmix`;
 580
 581} else {
 582
 583    my $mix = $dirname . "/.tmp_mx_" . $filename;
 584
 585    #
 586    # Step 8: Link the object with our list of call sites object.
 587    #
 588    `$ld -r $inputfile $mcount_o -o $mix`;
 589
 590    #
 591    # Step 9: Move the result back to the original object.
 592    #
 593    `$mv $mix $inputfile`;
 594}
 595
 596# Clean up the temp files
 597`$rm $mcount_o $mcount_s`;
 598
 599exit(0);
 600