LXR linux/scripts/recordmcount.pl

   1#!/usr/bin/perl -w
   2# (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3# Licensed under the terms of the GNU GPL License version 2
   4#
   5# recordmcount.pl - makes a section called __mcount_loc that holds
   6#                   all the offsets to the calls to mcount.
   7#
   8#
   9# What we want to end up with this is that each object file will have a
  10# section called __mcount_loc that will hold the list of pointers to mcount
  11# callers. After final linking, the vmlinux will have within .init.data the
  12# list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13# Later on boot up, the kernel will read this list, save the locations and turn
  14# them into nops. When tracing or profiling is later enabled, these locations
  15# will then be converted back to pointers to some function.
  16#
  17# This is no easy feat. This script is called just after the original
  18# object is compiled and before it is linked.
  19#
  20# When parse this object file using 'objdump', the references to the call
  21# sites are offsets from the section that the call site is in. Hence, all
  22# functions in a section that has a call site to mcount, will have the
  23# offset from the beginning of the section and not the beginning of the
  24# function.
  25#
  26# But where this section will reside finally in vmlinx is undetermined at
  27# this point. So we can't use this kind of offsets to record the final
  28# address of this call site.
  29#
  30# The trick is to change the call offset referring the start of a section to
  31# referring a function symbol in this section. During the link step, 'ld' will
  32# compute the final address according to the information we record.
  33#
  34# e.g.
  35#
  36#  .section ".sched.text", "ax"
  37#        [...]
  38#  func1:
  39#        [...]
  40#        call mcount  (offset: 0x10)
  41#        [...]
  42#        ret
  43#  .globl fun2
  44#  func2:             (offset: 0x20)
  45#        [...]
  46#        [...]
  47#        ret
  48#  func3:
  49#        [...]
  50#        call mcount (offset: 0x30)
  51#        [...]
  52#
  53# Both relocation offsets for the mcounts in the above example will be
  54# offset from .sched.text. If we choose global symbol func2 as a reference and
  55# make another file called tmp.s with the new offsets:
  56#
  57#  .section __mcount_loc
  58#  .quad  func2 - 0x10
  59#  .quad  func2 + 0x10
  60#
  61# We can then compile this tmp.s into tmp.o, and link it back to the original
  62# object.
  63#
  64# In our algorithm, we will choose the first global function we meet in this
  65# section as the reference. But this gets hard if there is no global functions
  66# in this section. In such a case we have to select a local one. E.g. func1:
  67#
  68#  .section ".sched.text", "ax"
  69#  func1:
  70#        [...]
  71#        call mcount  (offset: 0x10)
  72#        [...]
  73#        ret
  74#  func2:
  75#        [...]
  76#        call mcount (offset: 0x20)
  77#        [...]
  78#  .section "other.section"
  79#
  80# If we make the tmp.s the same as above, when we link together with
  81# the original object, we will end up with two symbols for func1:
  82# one local, one global.  After final compile, we will end up with
  83# an undefined reference to func1 or a wrong reference to another global
  84# func1 in other files.
  85#
  86# Since local objects can reference local variables, we need to find
  87# a way to make tmp.o reference the local objects of the original object
  88# file after it is linked together. To do this, we convert func1
  89# into a global symbol before linking tmp.o. Then after we link tmp.o
  90# we will only have a single symbol for func1 that is global.
  91# We can convert func1 back into a local symbol and we are done.
  92#
  93# Here are the steps we take:
  94#
  95# 1) Record all the local and weak symbols by using 'nm'
  96# 2) Use objdump to find all the call site offsets and sections for
  97#    mcount.
  98# 3) Compile the list into its own object.
  99# 4) Do we have to deal with local functions? If not, go to step 8.
 100# 5) Make an object that converts these local functions to global symbols
 101#    with objcopy.
 102# 6) Link together this new object with the list object.
 103# 7) Convert the local functions back to local symbols and rename
 104#    the result as the original object.
 105# 8) Link the object with the list object.
 106# 9) Move the result back to the original object.
 107#
 108
 109use strict;
 110
 111my $P = $0;
 112$P =~ s@.*/@@g;
 113
 114my $V = '0.1';
 115
 116if ($#ARGV != 11) {
 117        print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 118        print "version: $V\n";
 119        exit(1);
 120}
 121
 122my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
 123    $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 124
 125# This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 126if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 127    exit(0);
 128}
 129
 130# Acceptable sections to record.
 131my %text_sections = (
 132     ".text" => 1,
 133     ".init.text" => 1,
 134     ".ref.text" => 1,
 135     ".sched.text" => 1,
 136     ".spinlock.text" => 1,
 137     ".irqentry.text" => 1,
 138     ".softirqentry.text" => 1,
 139     ".kprobes.text" => 1,
 140     ".cpuidle.text" => 1,
 141     ".text.unlikely" => 1,
 142);
 143
 144# Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
 145$objdump = 'objdump' if (!$objdump);
 146$objcopy = 'objcopy' if (!$objcopy);
 147$cc = 'gcc' if (!$cc);
 148$ld = 'ld' if (!$ld);
 149$nm = 'nm' if (!$nm);
 150$rm = 'rm' if (!$rm);
 151$mv = 'mv' if (!$mv);
 152
 153#print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 154#    "'$nm' '$rm' '$mv' '$inputfile'\n";
 155
 156my %locals;             # List of local (static) functions
 157my %weak;               # List of weak functions
 158my %convert;            # List of local functions used that needs conversion
 159
 160my $type;
 161my $local_regex;        # Match a local function (return function)
 162my $weak_regex;         # Match a weak function (return function)
 163my $section_regex;      # Find the start of a section
 164my $function_regex;     # Find the name of a function
 165                        #    (return offset and func name)
 166my $mcount_regex;       # Find the call site to mcount (return offset)
 167my $mcount_adjust;      # Address adjustment to mcount offset
 168my $alignment;          # The .align value to use for $mcount_section
 169my $section_type;       # Section header plus possible alignment command
 170my $can_use_local = 0;  # If we can use local function references
 171
 172# Shut up recordmcount if user has older objcopy
 173my $quiet_recordmcount = ".tmp_quiet_recordmcount";
 174my $print_warning = 1;
 175$print_warning = 0 if ( -f $quiet_recordmcount);
 176
 177##
 178# check_objcopy - whether objcopy supports --globalize-symbols
 179#
 180#  --globalize-symbols came out in 2.17, we must test the version
 181#  of objcopy, and if it is less than 2.17, then we can not
 182#  record local functions.
 183sub check_objcopy
 184{
 185    open (IN, "$objcopy --version |") or die "error running $objcopy";
 186    while (<IN>) {
 187        if (/objcopy.*\s(\d+)\.(\d+)/) {
 188            $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
 189            last;
 190        }
 191    }
 192    close (IN);
 193
 194    if (!$can_use_local && $print_warning) {
 195        print STDERR "WARNING: could not find objcopy version or version " .
 196            "is less than 2.17.\n" .
 197            "\tLocal function references are disabled.\n";
 198        open (QUIET, ">$quiet_recordmcount");
 199        printf QUIET "Disables the warning from recordmcount.pl\n";
 200        close QUIET;
 201    }
 202}
 203
 204if ($arch =~ /(x86(_64)?)|(i386)/) {
 205    if ($bits == 64) {
 206        $arch = "x86_64";
 207    } else {
 208        $arch = "i386";
 209    }
 210}
 211
 212#
 213# We base the defaults off of i386, the other archs may
 214# feel free to change them in the below if statements.
 215#
 216$local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 217$weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 218$section_regex = "Disassembly of section\\s+(\\S+):";
 219$function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 220$mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)\$";
 221$section_type = '@progbits';
 222$mcount_adjust = 0;
 223$type = ".long";
 224
 225if ($arch eq "x86_64") {
 226    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)([+-]0x[0-9a-zA-Z]+)?\$";
 227    $type = ".quad";
 228    $alignment = 8;
 229    $mcount_adjust = -1;
 230
 231    # force flags for this arch
 232    $ld .= " -m elf_x86_64";
 233    $objdump .= " -M x86-64";
 234    $objcopy .= " -O elf64-x86-64";
 235    $cc .= " -m64";
 236
 237} elsif ($arch eq "i386") {
 238    $alignment = 4;
 239    $mcount_adjust = -1;
 240
 241    # force flags for this arch
 242    $ld .= " -m elf_i386";
 243    $objdump .= " -M i386";
 244    $objcopy .= " -O elf32-i386";
 245    $cc .= " -m32";
 246
 247} elsif ($arch eq "s390" && $bits == 64) {
 248    if ($cc =~ /-DCC_USING_HOTPATCH/) {
 249        $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*c0 04 00 00 00 00\\s*brcl\\s*0,[0-9a-f]+ <([^\+]*)>\$";
 250        $mcount_adjust = 0;
 251    } else {
 252        $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
 253        $mcount_adjust = -14;
 254    }
 255    $alignment = 8;
 256    $type = ".quad";
 257    $ld .= " -m elf64_s390";
 258    $cc .= " -m64";
 259
 260} elsif ($arch eq "sh") {
 261    $alignment = 2;
 262
 263    # force flags for this arch
 264    $ld .= " -m shlelf_linux";
 265    $objcopy .= " -O elf32-sh-linux";
 266
 267} elsif ($arch eq "powerpc") {
 268    $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 269    # See comment in the sparc64 section for why we use '\w'.
 270    $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?\\w*?)>:";
 271    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 272
 273    if ($bits == 64) {
 274        $type = ".quad";
 275    }
 276
 277} elsif ($arch eq "arm") {
 278    $alignment = 2;
 279    $section_type = '%progbits';
 280    $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
 281                        "\\s+(__gnu_mcount_nc|mcount)\$";
 282
 283} elsif ($arch eq "arm64") {
 284    $alignment = 3;
 285    $section_type = '%progbits';
 286    $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_AARCH64_CALL26\\s+_mcount\$";
 287    $type = ".quad";
 288} elsif ($arch eq "ia64") {
 289    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 290    $type = "data8";
 291
 292    if ($is_module eq "0") {
 293        $cc .= " -mconstant-gp";
 294    }
 295} elsif ($arch eq "sparc64") {
 296    # In the objdump output there are giblets like:
 297    # 0000000000000000 <igmp_net_exit-0x18>:
 298    # As there's some data blobs that get emitted into the
 299    # text section before the first instructions and the first
 300    # real symbols.  We don't want to match that, so to combat
 301    # this we use '\w' so we'll match just plain symbol names,
 302    # and not those that also include hex offsets inside of the
 303    # '<>' brackets.  Actually the generic function_regex setting
 304    # could safely use this too.
 305    $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 306
 307    # Sparc64 calls '_mcount' instead of plain 'mcount'.
 308    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 309
 310    $alignment = 8;
 311    $type = ".xword";
 312    $ld .= " -m elf64_sparc";
 313    $cc .= " -m64";
 314    $objcopy .= " -O elf64-sparc";
 315} elsif ($arch eq "mips") {
 316    # To enable module support, we need to enable the -mlong-calls option
 317    # of gcc for module, after using this option, we can not get the real
 318    # offset of the calling to _mcount, but the offset of the lui
 319    # instruction or the addiu one. herein, we record the address of the
 320    # first one, and then we can replace this instruction by a branch
 321    # instruction to jump over the profiling function to filter the
 322    # indicated functions, or switch back to the lui instruction to trace
 323    # them, which means dynamic tracing.
 324    #
 325    #       c:  3c030000        lui     v1,0x0
 326    #                   c: R_MIPS_HI16  _mcount
 327    #                   c: R_MIPS_NONE  *ABS*
 328    #                   c: R_MIPS_NONE  *ABS*
 329    #      10:  64630000        daddiu  v1,v1,0
 330    #                   10: R_MIPS_LO16 _mcount
 331    #                   10: R_MIPS_NONE *ABS*
 332    #                   10: R_MIPS_NONE *ABS*
 333    #      14:  03e0082d        move    at,ra
 334    #      18:  0060f809        jalr    v1
 335    #
 336    # for the kernel:
 337    #
 338    #     10:   03e0082d        move    at,ra
 339    #     14:   0c000000        jal     0 <loongson_halt>
 340    #                    14: R_MIPS_26   _mcount
 341    #                    14: R_MIPS_NONE *ABS*
 342    #                    14: R_MIPS_NONE *ABS*
 343    #    18:   00020021        nop
 344    if ($is_module eq "0") {
 345            $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
 346    } else {
 347            $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
 348    }
 349    $objdump .= " -Melf-trad".$endian."mips ";
 350
 351    if ($endian eq "big") {
 352            $endian = " -EB ";
 353            $ld .= " -melf".$bits."btsmip";
 354    } else {
 355            $endian = " -EL ";
 356            $ld .= " -melf".$bits."ltsmip";
 357    }
 358
 359    $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
 360    $ld .= $endian;
 361
 362    if ($bits == 64) {
 363            $function_regex =
 364                "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
 365            $type = ".dword";
 366    }
 367} elsif ($arch eq "microblaze") {
 368    # Microblaze calls '_mcount' instead of plain 'mcount'.
 369    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 370} elsif ($arch eq "blackfin") {
 371    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 372    $mcount_adjust = -4;
 373} elsif ($arch eq "tilegx" || $arch eq "tile") {
 374    # Default to the newer TILE-Gx architecture if only "tile" is given.
 375    $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 376    $type = ".quad";
 377    $alignment = 8;
 378} else {
 379    die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 380}
 381
 382my $text_found = 0;
 383my $read_function = 0;
 384my $opened = 0;
 385my $mcount_section = "__mcount_loc";
 386
 387my $dirname;
 388my $filename;
 389my $prefix;
 390my $ext;
 391
 392if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 393    $dirname = $1;
 394    $filename = $2;
 395} else {
 396    $dirname = ".";
 397    $filename = $inputfile;
 398}
 399
 400if ($filename =~ m,^(.*)(\.\S),) {
 401    $prefix = $1;
 402    $ext = $2;
 403} else {
 404    $prefix = $filename;
 405    $ext = "";
 406}
 407
 408my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 409my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 410
 411check_objcopy();
 412
 413#
 414# Step 1: find all the local (static functions) and weak symbols.
 415#         't' is local, 'w/W' is weak
 416#
 417open (IN, "$nm $inputfile|") || die "error running $nm";
 418while (<IN>) {
 419    if (/$local_regex/) {
 420        $locals{$1} = 1;
 421    } elsif (/$weak_regex/) {
 422        $weak{$2} = $1;
 423    }
 424}
 425close(IN);
 426
 427my @offsets;            # Array of offsets of mcount callers
 428my $ref_func;           # reference function to use for offsets
 429my $offset = 0;         # offset of ref_func to section beginning
 430
 431##
 432# update_funcs - print out the current mcount callers
 433#
 434#  Go through the list of offsets to callers and write them to
 435#  the output file in a format that can be read by an assembler.
 436#
 437sub update_funcs
 438{
 439    return unless ($ref_func and @offsets);
 440
 441    # Sanity check on weak function. A weak function may be overwritten by
 442    # another function of the same name, making all these offsets incorrect.
 443    if (defined $weak{$ref_func}) {
 444        die "$inputfile: ERROR: referencing weak function" .
 445            " $ref_func for mcount\n";
 446    }
 447
 448    # is this function static? If so, note this fact.
 449    if (defined $locals{$ref_func}) {
 450
 451        # only use locals if objcopy supports globalize-symbols
 452        if (!$can_use_local) {
 453            return;
 454        }
 455        $convert{$ref_func} = 1;
 456    }
 457
 458    # Loop through all the mcount caller offsets and print a reference
 459    # to the caller based from the ref_func.
 460    if (!$opened) {
 461        open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 462        $opened = 1;
 463        print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 464        print FILE "\t.align $alignment\n" if (defined($alignment));
 465    }
 466    foreach my $cur_offset (@offsets) {
 467        printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
 468    }
 469}
 470
 471#
 472# Step 2: find the sections and mcount call sites
 473#
 474open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
 475
 476my $text;
 477
 478
 479# read headers first
 480my $read_headers = 1;
 481
 482while (<IN>) {
 483
 484    if ($read_headers && /$mcount_section/) {
 485        #
 486        # Somehow the make process can execute this script on an
 487        # object twice. If it does, we would duplicate the mcount
 488        # section and it will cause the function tracer self test
 489        # to fail. Check if the mcount section exists, and if it does,
 490        # warn and exit.
 491        #
 492        print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 493            "\tThis may be an indication that your build is corrupted.\n" .
 494            "\tDelete $inputfile and try again. If the same object file\n" .
 495            "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 496        exit(-1);
 497    }
 498
 499    # is it a section?
 500    if (/$section_regex/) {
 501        $read_headers = 0;
 502
 503        # Only record text sections that we know are safe
 504        $read_function = defined($text_sections{$1});
 505        # print out any recorded offsets
 506        update_funcs();
 507
 508        # reset all markers and arrays
 509        $text_found = 0;
 510        undef($ref_func);
 511        undef(@offsets);
 512
 513    # section found, now is this a start of a function?
 514    } elsif ($read_function && /$function_regex/) {
 515        $text_found = 1;
 516        $text = $2;
 517
 518        # if this is either a local function or a weak function
 519        # keep looking for functions that are global that
 520        # we can use safely.
 521        if (!defined($locals{$text}) && !defined($weak{$text})) {
 522            $ref_func = $text;
 523            $read_function = 0;
 524            $offset = hex $1;
 525        } else {
 526            # if we already have a function, and this is weak, skip it
 527            if (!defined($ref_func) && !defined($weak{$text}) &&
 528                 # PPC64 can have symbols that start with .L and
 529                 # gcc considers these special. Don't use them!
 530                 $text !~ /^\.L/) {
 531                $ref_func = $text;
 532                $offset = hex $1;
 533            }
 534        }
 535    }
 536    # is this a call site to mcount? If so, record it to print later
 537    if ($text_found && /$mcount_regex/) {
 538        push(@offsets, (hex $1) + $mcount_adjust);
 539    }
 540}
 541
 542# dump out anymore offsets that may have been found
 543update_funcs();
 544
 545# If we did not find any mcount callers, we are done (do nothing).
 546if (!$opened) {
 547    exit(0);
 548}
 549
 550close(FILE);
 551
 552#
 553# Step 3: Compile the file that holds the list of call sites to mcount.
 554#
 555`$cc -o $mcount_o -c $mcount_s`;
 556
 557my @converts = keys %convert;
 558
 559#
 560# Step 4: Do we have sections that started with local functions?
 561#
 562if ($#converts >= 0) {
 563    my $globallist = "";
 564    my $locallist = "";
 565
 566    foreach my $con (@converts) {
 567        $globallist .= " --globalize-symbol $con";
 568        $locallist .= " --localize-symbol $con";
 569    }
 570
 571    my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 572    my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 573
 574    #
 575    # Step 5: set up each local function as a global
 576    #
 577    `$objcopy $globallist $inputfile $globalobj`;
 578
 579    #
 580    # Step 6: Link the global version to our list.
 581    #
 582    `$ld -r $globalobj $mcount_o -o $globalmix`;
 583
 584    #
 585    # Step 7: Convert the local functions back into local symbols
 586    #
 587    `$objcopy $locallist $globalmix $inputfile`;
 588
 589    # Remove the temp files
 590    `$rm $globalobj $globalmix`;
 591
 592} else {
 593
 594    my $mix = $dirname . "/.tmp_mx_" . $filename;
 595
 596    #
 597    # Step 8: Link the object with our list of call sites object.
 598    #
 599    `$ld -r $inputfile $mcount_o -o $mix`;
 600
 601    #
 602    # Step 9: Move the result back to the original object.
 603    #
 604    `$mv $mix $inputfile`;
 605}
 606
 607# Clean up the temp files
 608`$rm $mcount_o $mcount_s`;
 609
 610exit(0);
 611