LXR linux/arch/sparc/lib/NG4patch.S

   1/* SPDX-License-Identifier: GPL-2.0 */
   2/* NG4patch.S: Patch Ultra-I routines with Niagara-4 variant.
   3 *
   4 * Copyright (C) 2012 David S. Miller <davem@davemloft.net>
   5 */
   6
   7#define BRANCH_ALWAYS   0x10680000
   8#define NOP             0x01000000
   9#define NG_DO_PATCH(OLD, NEW)   \
  10        sethi   %hi(NEW), %g1; \
  11        or      %g1, %lo(NEW), %g1; \
  12        sethi   %hi(OLD), %g2; \
  13        or      %g2, %lo(OLD), %g2; \
  14        sub     %g1, %g2, %g1; \
  15        sethi   %hi(BRANCH_ALWAYS), %g3; \
  16        sll     %g1, 11, %g1; \
  17        srl     %g1, 11 + 2, %g1; \
  18        or      %g3, %lo(BRANCH_ALWAYS), %g3; \
  19        or      %g3, %g1, %g3; \
  20        stw     %g3, [%g2]; \
  21        sethi   %hi(NOP), %g3; \
  22        or      %g3, %lo(NOP), %g3; \
  23        stw     %g3, [%g2 + 0x4]; \
  24        flush   %g2;
  25
  26        .globl  niagara4_patch_copyops
  27        .type   niagara4_patch_copyops,#function
  28niagara4_patch_copyops:
  29        NG_DO_PATCH(memcpy, NG4memcpy)
  30        NG_DO_PATCH(raw_copy_from_user, NG4copy_from_user)
  31        NG_DO_PATCH(raw_copy_to_user, NG4copy_to_user)
  32        retl
  33         nop
  34        .size   niagara4_patch_copyops,.-niagara4_patch_copyops
  35
  36        .globl  niagara4_patch_bzero
  37        .type   niagara4_patch_bzero,#function
  38niagara4_patch_bzero:
  39        NG_DO_PATCH(memset, NG4memset)
  40        NG_DO_PATCH(__bzero, NG4bzero)
  41        NG_DO_PATCH(__clear_user, NGclear_user)
  42        NG_DO_PATCH(tsb_init, NGtsb_init)
  43        retl
  44         nop
  45        .size   niagara4_patch_bzero,.-niagara4_patch_bzero
  46
  47        .globl  niagara4_patch_pageops
  48        .type   niagara4_patch_pageops,#function
  49niagara4_patch_pageops:
  50        NG_DO_PATCH(copy_user_page, NG4copy_user_page)
  51        NG_DO_PATCH(_clear_page, NG4clear_page)
  52        NG_DO_PATCH(clear_user_page, NG4clear_user_page)
  53        retl
  54         nop
  55        .size   niagara4_patch_pageops,.-niagara4_patch_pageops
  56