LXR linux/arch/parisc/kernel/vmlinux.lds.S

   1/*    Kernel link layout for various "sections"
   2 *
   3 *    Copyright (C) 1999-2003 Matthew Wilcox <willy at parisc-linux.org>
   4 *    Copyright (C) 2000-2003 Paul Bame <bame at parisc-linux.org>
   5 *    Copyright (C) 2000 John Marvin <jsm at parisc-linux.org>
   6 *    Copyright (C) 2000 Michael Ang <mang with subcarrier.org>
   7 *    Copyright (C) 2002 Randolph Chung <tausq with parisc-linux.org>
   8 *    Copyright (C) 2003 James Bottomley <jejb with parisc-linux.org>
   9 *    Copyright (C) 2006-2013 Helge Deller <deller@gmx.de>
  10 */
  11
  12/*
  13 * Put page table entries (swapper_pg_dir) as the first thing in .bss. This
  14 * will ensure that it has .bss alignment (PAGE_SIZE).
  15 */
  16#define BSS_FIRST_SECTIONS      *(.data..vm0.pmd) \
  17                                *(.data..vm0.pgd) \
  18                                *(.data..vm0.pte)
  19
  20#include <asm-generic/vmlinux.lds.h>
  21
  22/* needed for the processor specific cache alignment size */    
  23#include <asm/cache.h>
  24#include <asm/page.h>
  25#include <asm/asm-offsets.h>
  26#include <asm/thread_info.h>
  27        
  28/* ld script to make hppa Linux kernel */
  29#ifndef CONFIG_64BIT
  30OUTPUT_FORMAT("elf32-hppa-linux")
  31OUTPUT_ARCH(hppa)
  32#else
  33OUTPUT_FORMAT("elf64-hppa-linux")
  34OUTPUT_ARCH(hppa:hppa2.0w)
  35#endif
  36
  37ENTRY(parisc_kernel_start)
  38#ifndef CONFIG_64BIT
  39jiffies = jiffies_64 + 4;
  40#else
  41jiffies = jiffies_64;
  42#endif
  43SECTIONS
  44{
  45        . = KERNEL_BINARY_TEXT_START;
  46
  47        __init_begin = .;
  48        HEAD_TEXT_SECTION
  49        INIT_TEXT_SECTION(8)
  50
  51        . = ALIGN(PAGE_SIZE);
  52        INIT_DATA_SECTION(PAGE_SIZE)
  53        /* we have to discard exit text and such at runtime, not link time */
  54        .exit.text :
  55        {
  56                EXIT_TEXT
  57        }
  58        .exit.data :
  59        {
  60                EXIT_DATA
  61        }
  62        PERCPU_SECTION(8)
  63        . = ALIGN(PAGE_SIZE);
  64        __init_end = .;
  65        /* freed after init ends here */
  66
  67        _text = .;              /* Text and read-only data */
  68        _stext = .;
  69        .text ALIGN(PAGE_SIZE) : {
  70                TEXT_TEXT
  71                SCHED_TEXT
  72                LOCK_TEXT
  73                KPROBES_TEXT
  74                IRQENTRY_TEXT
  75                *(.text.do_softirq)
  76                *(.text.sys_exit)
  77                *(.text.do_sigaltstack)
  78                *(.text.do_fork)
  79                *(.text.*)
  80                *(.fixup)
  81                *(.lock.text)           /* out-of-line lock text */
  82                *(.gnu.warning)
  83        }
  84        . = ALIGN(PAGE_SIZE);
  85        _etext = .;
  86        /* End of text section */
  87
  88        /* Start of data section */
  89        _sdata = .;
  90
  91        RO_DATA_SECTION(8)
  92
  93#ifdef CONFIG_64BIT
  94        . = ALIGN(16);
  95        /* Linkage tables */
  96        .opd : {
  97                *(.opd)
  98        } PROVIDE (__gp = .);
  99        .plt : {
 100                *(.plt)
 101        }
 102        .dlt : {
 103                *(.dlt)
 104        }
 105#endif
 106
 107        /* unwind info */
 108        .PARISC.unwind : {
 109                __start___unwind = .;
 110                *(.PARISC.unwind)
 111                __stop___unwind = .;
 112        }
 113
 114        /* writeable */
 115        /* Make sure this is page aligned so
 116         * that we can properly leave these
 117         * as writable
 118         */
 119        . = ALIGN(PAGE_SIZE);
 120        data_start = .;
 121
 122        EXCEPTION_TABLE(8)
 123        NOTES
 124
 125        /* Data */
 126        RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, PAGE_SIZE)
 127
 128        /* PA-RISC locks requires 16-byte alignment */
 129        . = ALIGN(16);
 130        .data..lock_aligned : {
 131                *(.data..lock_aligned)
 132        }
 133
 134        /* End of data section */
 135        _edata = .;
 136
 137        /* BSS */
 138        BSS_SECTION(PAGE_SIZE, PAGE_SIZE, 8)
 139
 140        _end = . ;
 141
 142        STABS_DEBUG
 143        .note 0 : { *(.note) }
 144
 145        /* Sections to be discarded */
 146        DISCARDS
 147        /DISCARD/ : {
 148#ifdef CONFIG_64BIT
 149                /* temporary hack until binutils is fixed to not emit these
 150                 * for static binaries
 151                 */
 152                *(.interp)
 153                *(.dynsym)
 154                *(.dynstr)
 155                *(.dynamic)
 156                *(.hash)
 157                *(.gnu.hash)
 158#endif
 159        }
 160}
 161