LXR linux/arch/unicore32/kernel/vmlinux.lds.S

   1/* SPDX-License-Identifier: GPL-2.0-only */
   2/*
   3 * linux/arch/unicore32/kernel/vmlinux.lds.S
   4 *
   5 * Code specific to PKUnity SoC and UniCore ISA
   6 *
   7 * Copyright (C) 2001-2010 GUAN Xue-tao
   8 */
   9
  10#include <asm-generic/vmlinux.lds.h>
  11#include <asm/thread_info.h>
  12#include <asm/memory.h>
  13#include <asm/page.h>
  14#include <asm/cache.h>
  15
  16OUTPUT_ARCH(unicore32)
  17ENTRY(stext)
  18
  19jiffies = jiffies_64;
  20
  21SECTIONS
  22{
  23        . = PAGE_OFFSET + KERNEL_IMAGE_START;
  24
  25        _text = .;
  26        __init_begin = .;
  27        HEAD_TEXT_SECTION
  28        INIT_TEXT_SECTION(PAGE_SIZE)
  29        INIT_DATA_SECTION(16)
  30        PERCPU_SECTION(L1_CACHE_BYTES)
  31        __init_end = .;
  32
  33        _stext = .;
  34        .text : {               /* Real text segment */
  35                TEXT_TEXT
  36                SCHED_TEXT
  37                CPUIDLE_TEXT
  38                LOCK_TEXT
  39
  40                *(.fixup)
  41                *(.gnu.warning)
  42        }
  43        _etext = .;
  44
  45        _sdata = .;
  46        RO_DATA_SECTION(PAGE_SIZE)
  47        RW_DATA_SECTION(L1_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
  48        _edata = .;
  49
  50        EXCEPTION_TABLE(L1_CACHE_BYTES)
  51        NOTES
  52
  53        BSS_SECTION(0, 0, 0)
  54        _end = .;
  55
  56        STABS_DEBUG
  57        DWARF_DEBUG
  58
  59        DISCARDS                /* Exit code and data */
  60}
  61