LXR linux/arch/arm64/include/asm/asm-uaccess.h

   1/* SPDX-License-Identifier: GPL-2.0 */
   2#ifndef __ASM_ASM_UACCESS_H
   3#define __ASM_ASM_UACCESS_H
   4
   5#include <asm/alternative.h>
   6#include <asm/kernel-pgtable.h>
   7#include <asm/mmu.h>
   8#include <asm/sysreg.h>
   9#include <asm/assembler.h>
  10
  11/*
  12 * User access enabling/disabling macros.
  13 */
  14#ifdef CONFIG_ARM64_SW_TTBR0_PAN
  15        .macro  __uaccess_ttbr0_disable, tmp1
  16        mrs     \tmp1, ttbr1_el1                        // swapper_pg_dir
  17        bic     \tmp1, \tmp1, #TTBR_ASID_MASK
  18        sub     \tmp1, \tmp1, #RESERVED_TTBR0_SIZE      // reserved_ttbr0 just before swapper_pg_dir
  19        msr     ttbr0_el1, \tmp1                        // set reserved TTBR0_EL1
  20        isb
  21        add     \tmp1, \tmp1, #RESERVED_TTBR0_SIZE
  22        msr     ttbr1_el1, \tmp1                // set reserved ASID
  23        isb
  24        .endm
  25
  26        .macro  __uaccess_ttbr0_enable, tmp1, tmp2
  27        get_current_task \tmp1
  28        ldr     \tmp1, [\tmp1, #TSK_TI_TTBR0]   // load saved TTBR0_EL1
  29        mrs     \tmp2, ttbr1_el1
  30        extr    \tmp2, \tmp2, \tmp1, #48
  31        ror     \tmp2, \tmp2, #16
  32        msr     ttbr1_el1, \tmp2                // set the active ASID
  33        isb
  34        msr     ttbr0_el1, \tmp1                // set the non-PAN TTBR0_EL1
  35        isb
  36        .endm
  37
  38        .macro  uaccess_ttbr0_disable, tmp1, tmp2
  39alternative_if_not ARM64_HAS_PAN
  40        save_and_disable_irq \tmp2              // avoid preemption
  41        __uaccess_ttbr0_disable \tmp1
  42        restore_irq \tmp2
  43alternative_else_nop_endif
  44        .endm
  45
  46        .macro  uaccess_ttbr0_enable, tmp1, tmp2, tmp3
  47alternative_if_not ARM64_HAS_PAN
  48        save_and_disable_irq \tmp3              // avoid preemption
  49        __uaccess_ttbr0_enable \tmp1, \tmp2
  50        restore_irq \tmp3
  51alternative_else_nop_endif
  52        .endm
  53#else
  54        .macro  uaccess_ttbr0_disable, tmp1, tmp2
  55        .endm
  56
  57        .macro  uaccess_ttbr0_enable, tmp1, tmp2, tmp3
  58        .endm
  59#endif
  60
  61/*
  62 * These macros are no-ops when UAO is present.
  63 */
  64        .macro  uaccess_disable_not_uao, tmp1, tmp2
  65        uaccess_ttbr0_disable \tmp1, \tmp2
  66alternative_if ARM64_ALT_PAN_NOT_UAO
  67        SET_PSTATE_PAN(1)
  68alternative_else_nop_endif
  69        .endm
  70
  71        .macro  uaccess_enable_not_uao, tmp1, tmp2, tmp3
  72        uaccess_ttbr0_enable \tmp1, \tmp2, \tmp3
  73alternative_if ARM64_ALT_PAN_NOT_UAO
  74        SET_PSTATE_PAN(0)
  75alternative_else_nop_endif
  76        .endm
  77
  78/*
  79 * Remove the address tag from a virtual address, if present.
  80 */
  81        .macro  clear_address_tag, dst, addr
  82        tst     \addr, #(1 << 55)
  83        bic     \dst, \addr, #(0xff << 56)
  84        csel    \dst, \dst, \addr, eq
  85        .endm
  86
  87#endif
  88