LXR linux/arch/x86/kernel/head

   1/* SPDX-License-Identifier: GPL-2.0 */
   2/*
   3 *
   4 *  Copyright (C) 1991, 1992  Linus Torvalds
   5 *
   6 *  Enhanced CPU detection and feature setting code by Mike Jagdis
   7 *  and Martin Mares, November 1997.
   8 */
   9
  10.text
  11#include <linux/threads.h>
  12#include <linux/init.h>
  13#include <linux/linkage.h>
  14#include <asm/segment.h>
  15#include <asm/page_types.h>
  16#include <asm/pgtable_types.h>
  17#include <asm/cache.h>
  18#include <asm/thread_info.h>
  19#include <asm/asm-offsets.h>
  20#include <asm/setup.h>
  21#include <asm/processor-flags.h>
  22#include <asm/msr-index.h>
  23#include <asm/cpufeatures.h>
  24#include <asm/percpu.h>
  25#include <asm/nops.h>
  26#include <asm/bootparam.h>
  27#include <asm/export.h>
  28#include <asm/pgtable_32.h>
  29
  30/* Physical address */
  31#define pa(X) ((X) - __PAGE_OFFSET)
  32
  33/*
  34 * References to members of the new_cpu_data structure.
  35 */
  36
  37#define X86             new_cpu_data+CPUINFO_x86
  38#define X86_VENDOR      new_cpu_data+CPUINFO_x86_vendor
  39#define X86_MODEL       new_cpu_data+CPUINFO_x86_model
  40#define X86_STEPPING    new_cpu_data+CPUINFO_x86_stepping
  41#define X86_HARD_MATH   new_cpu_data+CPUINFO_hard_math
  42#define X86_CPUID       new_cpu_data+CPUINFO_cpuid_level
  43#define X86_CAPABILITY  new_cpu_data+CPUINFO_x86_capability
  44#define X86_VENDOR_ID   new_cpu_data+CPUINFO_x86_vendor_id
  45
  46
  47#define SIZEOF_PTREGS 17*4
  48
  49/*
  50 * Worst-case size of the kernel mapping we need to make:
  51 * a relocatable kernel can live anywhere in lowmem, so we need to be able
  52 * to map all of lowmem.
  53 */
  54KERNEL_PAGES = LOWMEM_PAGES
  55
  56INIT_MAP_SIZE = PAGE_TABLE_SIZE(KERNEL_PAGES) * PAGE_SIZE
  57RESERVE_BRK(pagetables, INIT_MAP_SIZE)
  58
  59/*
  60 * 32-bit kernel entrypoint; only used by the boot CPU.  On entry,
  61 * %esi points to the real-mode code as a 32-bit pointer.
  62 * CS and DS must be 4 GB flat segments, but we don't depend on
  63 * any particular GDT layout, because we load our own as soon as we
  64 * can.
  65 */
  66__HEAD
  67SYM_CODE_START(startup_32)
  68        movl pa(initial_stack),%ecx
  69        
  70/*
  71 * Set segments to known values.
  72 */
  73        lgdt pa(boot_gdt_descr)
  74        movl $(__BOOT_DS),%eax
  75        movl %eax,%ds
  76        movl %eax,%es
  77        movl %eax,%fs
  78        movl %eax,%gs
  79        movl %eax,%ss
  80        leal -__PAGE_OFFSET(%ecx),%esp
  81
  82/*
  83 * Clear BSS first so that there are no surprises...
  84 */
  85        cld
  86        xorl %eax,%eax
  87        movl $pa(__bss_start),%edi
  88        movl $pa(__bss_stop),%ecx
  89        subl %edi,%ecx
  90        shrl $2,%ecx
  91        rep ; stosl
  92/*
  93 * Copy bootup parameters out of the way.
  94 * Note: %esi still has the pointer to the real-mode data.
  95 * With the kexec as boot loader, parameter segment might be loaded beyond
  96 * kernel image and might not even be addressable by early boot page tables.
  97 * (kexec on panic case). Hence copy out the parameters before initializing
  98 * page tables.
  99 */
 100        movl $pa(boot_params),%edi
 101        movl $(PARAM_SIZE/4),%ecx
 102        cld
 103        rep
 104        movsl
 105        movl pa(boot_params) + NEW_CL_POINTER,%esi
 106        andl %esi,%esi
 107        jz 1f                   # No command line
 108        movl $pa(boot_command_line),%edi
 109        movl $(COMMAND_LINE_SIZE/4),%ecx
 110        rep
 111        movsl
 1121:
 113
 114#ifdef CONFIG_OLPC
 115        /* save OFW's pgdir table for later use when calling into OFW */
 116        movl %cr3, %eax
 117        movl %eax, pa(olpc_ofw_pgd)
 118#endif
 119
 120#ifdef CONFIG_MICROCODE
 121        /* Early load ucode on BSP. */
 122        call load_ucode_bsp
 123#endif
 124
 125        /* Create early pagetables. */
 126        call  mk_early_pgtbl_32
 127
 128        /* Do early initialization of the fixmap area */
 129        movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
 130#ifdef  CONFIG_X86_PAE
 131#define KPMDS (((-__PAGE_OFFSET) >> 30) & 3) /* Number of kernel PMDs */
 132        movl %eax,pa(initial_pg_pmd+0x1000*KPMDS-8)
 133#else
 134        movl %eax,pa(initial_page_table+0xffc)
 135#endif
 136
 137#ifdef CONFIG_PARAVIRT
 138        /* This is can only trip for a broken bootloader... */
 139        cmpw $0x207, pa(boot_params + BP_version)
 140        jb .Ldefault_entry
 141
 142        /* Paravirt-compatible boot parameters.  Look to see what architecture
 143                we're booting under. */
 144        movl pa(boot_params + BP_hardware_subarch), %eax
 145        cmpl $num_subarch_entries, %eax
 146        jae .Lbad_subarch
 147
 148        movl pa(subarch_entries)(,%eax,4), %eax
 149        subl $__PAGE_OFFSET, %eax
 150        jmp *%eax
 151
 152.Lbad_subarch:
 153SYM_INNER_LABEL_ALIGN(xen_entry, SYM_L_WEAK)
 154        /* Unknown implementation; there's really
 155           nothing we can do at this point. */
 156        ud2a
 157
 158        __INITDATA
 159
 160subarch_entries:
 161        .long .Ldefault_entry           /* normal x86/PC */
 162        .long xen_entry                 /* Xen hypervisor */
 163        .long .Ldefault_entry           /* Moorestown MID */
 164num_subarch_entries = (. - subarch_entries) / 4
 165.previous
 166#else
 167        jmp .Ldefault_entry
 168#endif /* CONFIG_PARAVIRT */
 169SYM_CODE_END(startup_32)
 170
 171#ifdef CONFIG_HOTPLUG_CPU
 172/*
 173 * Boot CPU0 entry point. It's called from play_dead(). Everything has been set
 174 * up already except stack. We just set up stack here. Then call
 175 * start_secondary().
 176 */
 177SYM_FUNC_START(start_cpu0)
 178        movl initial_stack, %ecx
 179        movl %ecx, %esp
 180        call *(initial_code)
 1811:      jmp 1b
 182SYM_FUNC_END(start_cpu0)
 183#endif
 184
 185/*
 186 * Non-boot CPU entry point; entered from trampoline.S
 187 * We can't lgdt here, because lgdt itself uses a data segment, but
 188 * we know the trampoline has already loaded the boot_gdt for us.
 189 *
 190 * If cpu hotplug is not supported then this code can go in init section
 191 * which will be freed later
 192 */
 193SYM_FUNC_START(startup_32_smp)
 194        cld
 195        movl $(__BOOT_DS),%eax
 196        movl %eax,%ds
 197        movl %eax,%es
 198        movl %eax,%fs
 199        movl %eax,%gs
 200        movl pa(initial_stack),%ecx
 201        movl %eax,%ss
 202        leal -__PAGE_OFFSET(%ecx),%esp
 203
 204#ifdef CONFIG_MICROCODE
 205        /* Early load ucode on AP. */
 206        call load_ucode_ap
 207#endif
 208
 209.Ldefault_entry:
 210        movl $(CR0_STATE & ~X86_CR0_PG),%eax
 211        movl %eax,%cr0
 212
 213/*
 214 * We want to start out with EFLAGS unambiguously cleared. Some BIOSes leave
 215 * bits like NT set. This would confuse the debugger if this code is traced. So
 216 * initialize them properly now before switching to protected mode. That means
 217 * DF in particular (even though we have cleared it earlier after copying the
 218 * command line) because GCC expects it.
 219 */
 220        pushl $0
 221        popfl
 222
 223/*
 224 * New page tables may be in 4Mbyte page mode and may be using the global pages.
 225 *
 226 * NOTE! If we are on a 486 we may have no cr4 at all! Specifically, cr4 exists
 227 * if and only if CPUID exists and has flags other than the FPU flag set.
 228 */
 229        movl $-1,pa(X86_CPUID)          # preset CPUID level
 230        movl $X86_EFLAGS_ID,%ecx
 231        pushl %ecx
 232        popfl                           # set EFLAGS=ID
 233        pushfl
 234        popl %eax                       # get EFLAGS
 235        testl $X86_EFLAGS_ID,%eax       # did EFLAGS.ID remained set?
 236        jz .Lenable_paging              # hw disallowed setting of ID bit
 237                                        # which means no CPUID and no CR4
 238
 239        xorl %eax,%eax
 240        cpuid
 241        movl %eax,pa(X86_CPUID)         # save largest std CPUID function
 242
 243        movl $1,%eax
 244        cpuid
 245        andl $~1,%edx                   # Ignore CPUID.FPU
 246        jz .Lenable_paging              # No flags or only CPUID.FPU = no CR4
 247
 248        movl pa(mmu_cr4_features),%eax
 249        movl %eax,%cr4
 250
 251        testb $X86_CR4_PAE, %al         # check if PAE is enabled
 252        jz .Lenable_paging
 253
 254        /* Check if extended functions are implemented */
 255        movl $0x80000000, %eax
 256        cpuid
 257        /* Value must be in the range 0x80000001 to 0x8000ffff */
 258        subl $0x80000001, %eax
 259        cmpl $(0x8000ffff-0x80000001), %eax
 260        ja .Lenable_paging
 261
 262        /* Clear bogus XD_DISABLE bits */
 263        call verify_cpu
 264
 265        mov $0x80000001, %eax
 266        cpuid
 267        /* Execute Disable bit supported? */
 268        btl $(X86_FEATURE_NX & 31), %edx
 269        jnc .Lenable_paging
 270
 271        /* Setup EFER (Extended Feature Enable Register) */
 272        movl $MSR_EFER, %ecx
 273        rdmsr
 274
 275        btsl $_EFER_NX, %eax
 276        /* Make changes effective */
 277        wrmsr
 278
 279.Lenable_paging:
 280
 281/*
 282 * Enable paging
 283 */
 284        movl $pa(initial_page_table), %eax
 285        movl %eax,%cr3          /* set the page table pointer.. */
 286        movl $CR0_STATE,%eax
 287        movl %eax,%cr0          /* ..and set paging (PG) bit */
 288        ljmp $__BOOT_CS,$1f     /* Clear prefetch and normalize %eip */
 2891:
 290        /* Shift the stack pointer to a virtual address */
 291        addl $__PAGE_OFFSET, %esp
 292
 293/*
 294 * start system 32-bit setup. We need to re-do some of the things done
 295 * in 16-bit mode for the "real" operations.
 296 */
 297        movl setup_once_ref,%eax
 298        andl %eax,%eax
 299        jz 1f                           # Did we do this already?
 300        call *%eax
 3011:
 302
 303/*
 304 * Check if it is 486
 305 */
 306        movb $4,X86                     # at least 486
 307        cmpl $-1,X86_CPUID
 308        je .Lis486
 309
 310        /* get vendor info */
 311        xorl %eax,%eax                  # call CPUID with 0 -> return vendor ID
 312        cpuid
 313        movl %eax,X86_CPUID             # save CPUID level
 314        movl %ebx,X86_VENDOR_ID         # lo 4 chars
 315        movl %edx,X86_VENDOR_ID+4       # next 4 chars
 316        movl %ecx,X86_VENDOR_ID+8       # last 4 chars
 317
 318        orl %eax,%eax                   # do we have processor info as well?
 319        je .Lis486
 320
 321        movl $1,%eax            # Use the CPUID instruction to get CPU type
 322        cpuid
 323        movb %al,%cl            # save reg for future use
 324        andb $0x0f,%ah          # mask processor family
 325        movb %ah,X86
 326        andb $0xf0,%al          # mask model
 327        shrb $4,%al
 328        movb %al,X86_MODEL
 329        andb $0x0f,%cl          # mask mask revision
 330        movb %cl,X86_STEPPING
 331        movl %edx,X86_CAPABILITY
 332
 333.Lis486:
 334        movl $0x50022,%ecx      # set AM, WP, NE and MP
 335        movl %cr0,%eax
 336        andl $0x80000011,%eax   # Save PG,PE,ET
 337        orl %ecx,%eax
 338        movl %eax,%cr0
 339
 340        lgdt early_gdt_descr
 341        ljmp $(__KERNEL_CS),$1f
 3421:      movl $(__KERNEL_DS),%eax        # reload all the segment registers
 343        movl %eax,%ss                   # after changing gdt.
 344
 345        movl $(__USER_DS),%eax          # DS/ES contains default USER segment
 346        movl %eax,%ds
 347        movl %eax,%es
 348
 349        movl $(__KERNEL_PERCPU), %eax
 350        movl %eax,%fs                   # set this cpu's percpu
 351
 352        movl $(__KERNEL_STACK_CANARY),%eax
 353        movl %eax,%gs
 354
 355        xorl %eax,%eax                  # Clear LDT
 356        lldt %ax
 357
 358        call *(initial_code)
 3591:      jmp 1b
 360SYM_FUNC_END(startup_32_smp)
 361
 362#include "verify_cpu.S"
 363
 364/*
 365 *  setup_once
 366 *
 367 *  The setup work we only want to run on the BSP.
 368 *
 369 *  Warning: %esi is live across this function.
 370 */
 371__INIT
 372setup_once:
 373#ifdef CONFIG_STACKPROTECTOR
 374        /*
 375         * Configure the stack canary. The linker can't handle this by
 376         * relocation.  Manually set base address in stack canary
 377         * segment descriptor.
 378         */
 379        movl $gdt_page,%eax
 380        movl $stack_canary,%ecx
 381        movw %cx, 8 * GDT_ENTRY_STACK_CANARY + 2(%eax)
 382        shrl $16, %ecx
 383        movb %cl, 8 * GDT_ENTRY_STACK_CANARY + 4(%eax)
 384        movb %ch, 8 * GDT_ENTRY_STACK_CANARY + 7(%eax)
 385#endif
 386
 387        andl $0,setup_once_ref  /* Once is enough, thanks */
 388        ret
 389
 390SYM_FUNC_START(early_idt_handler_array)
 391        # 36(%esp) %eflags
 392        # 32(%esp) %cs
 393        # 28(%esp) %eip
 394        # 24(%rsp) error code
 395        i = 0
 396        .rept NUM_EXCEPTION_VECTORS
 397        .if ((EXCEPTION_ERRCODE_MASK >> i) & 1) == 0
 398        pushl $0                # Dummy error code, to make stack frame uniform
 399        .endif
 400        pushl $i                # 20(%esp) Vector number
 401        jmp early_idt_handler_common
 402        i = i + 1
 403        .fill early_idt_handler_array + i*EARLY_IDT_HANDLER_SIZE - ., 1, 0xcc
 404        .endr
 405SYM_FUNC_END(early_idt_handler_array)
 406        
 407SYM_CODE_START_LOCAL(early_idt_handler_common)
 408        /*
 409         * The stack is the hardware frame, an error code or zero, and the
 410         * vector number.
 411         */
 412        cld
 413
 414        incl %ss:early_recursion_flag
 415
 416        /* The vector number is in pt_regs->gs */
 417
 418        cld
 419        pushl   %fs             /* pt_regs->fs (__fsh varies by model) */
 420        pushl   %es             /* pt_regs->es (__esh varies by model) */
 421        pushl   %ds             /* pt_regs->ds (__dsh varies by model) */
 422        pushl   %eax            /* pt_regs->ax */
 423        pushl   %ebp            /* pt_regs->bp */
 424        pushl   %edi            /* pt_regs->di */
 425        pushl   %esi            /* pt_regs->si */
 426        pushl   %edx            /* pt_regs->dx */
 427        pushl   %ecx            /* pt_regs->cx */
 428        pushl   %ebx            /* pt_regs->bx */
 429
 430        /* Fix up DS and ES */
 431        movl    $(__KERNEL_DS), %ecx
 432        movl    %ecx, %ds
 433        movl    %ecx, %es
 434
 435        /* Load the vector number into EDX */
 436        movl    PT_GS(%esp), %edx
 437
 438        /* Load GS into pt_regs->gs (and maybe clobber __gsh) */
 439        movw    %gs, PT_GS(%esp)
 440
 441        movl    %esp, %eax      /* args are pt_regs (EAX), trapnr (EDX) */
 442        call    early_fixup_exception
 443
 444        popl    %ebx            /* pt_regs->bx */
 445        popl    %ecx            /* pt_regs->cx */
 446        popl    %edx            /* pt_regs->dx */
 447        popl    %esi            /* pt_regs->si */
 448        popl    %edi            /* pt_regs->di */
 449        popl    %ebp            /* pt_regs->bp */
 450        popl    %eax            /* pt_regs->ax */
 451        popl    %ds             /* pt_regs->ds (always ignores __dsh) */
 452        popl    %es             /* pt_regs->es (always ignores __esh) */
 453        popl    %fs             /* pt_regs->fs (always ignores __fsh) */
 454        popl    %gs             /* pt_regs->gs (always ignores __gsh) */
 455        decl    %ss:early_recursion_flag
 456        addl    $4, %esp        /* pop pt_regs->orig_ax */
 457        iret
 458SYM_CODE_END(early_idt_handler_common)
 459
 460/* This is the default interrupt "handler" :-) */
 461SYM_FUNC_START(early_ignore_irq)
 462        cld
 463#ifdef CONFIG_PRINTK
 464        pushl %eax
 465        pushl %ecx
 466        pushl %edx
 467        pushl %es
 468        pushl %ds
 469        movl $(__KERNEL_DS),%eax
 470        movl %eax,%ds
 471        movl %eax,%es
 472        cmpl $2,early_recursion_flag
 473        je hlt_loop
 474        incl early_recursion_flag
 475        pushl 16(%esp)
 476        pushl 24(%esp)
 477        pushl 32(%esp)
 478        pushl 40(%esp)
 479        pushl $int_msg
 480        call printk
 481
 482        call dump_stack
 483
 484        addl $(5*4),%esp
 485        popl %ds
 486        popl %es
 487        popl %edx
 488        popl %ecx
 489        popl %eax
 490#endif
 491        iret
 492
 493hlt_loop:
 494        hlt
 495        jmp hlt_loop
 496SYM_FUNC_END(early_ignore_irq)
 497
 498__INITDATA
 499        .align 4
 500SYM_DATA(early_recursion_flag, .long 0)
 501
 502__REFDATA
 503        .align 4
 504SYM_DATA(initial_code,          .long i386_start_kernel)
 505SYM_DATA(setup_once_ref,        .long setup_once)
 506
 507#ifdef CONFIG_PAGE_TABLE_ISOLATION
 508#define PGD_ALIGN       (2 * PAGE_SIZE)
 509#define PTI_USER_PGD_FILL       1024
 510#else
 511#define PGD_ALIGN       (PAGE_SIZE)
 512#define PTI_USER_PGD_FILL       0
 513#endif
 514/*
 515 * BSS section
 516 */
 517__PAGE_ALIGNED_BSS
 518        .align PGD_ALIGN
 519#ifdef CONFIG_X86_PAE
 520.globl initial_pg_pmd
 521initial_pg_pmd:
 522        .fill 1024*KPMDS,4,0
 523#else
 524.globl initial_page_table
 525initial_page_table:
 526        .fill 1024,4,0
 527#endif
 528        .align PGD_ALIGN
 529initial_pg_fixmap:
 530        .fill 1024,4,0
 531.globl swapper_pg_dir
 532        .align PGD_ALIGN
 533swapper_pg_dir:
 534        .fill 1024,4,0
 535        .fill PTI_USER_PGD_FILL,4,0
 536.globl empty_zero_page
 537empty_zero_page:
 538        .fill 4096,1,0
 539EXPORT_SYMBOL(empty_zero_page)
 540
 541/*
 542 * This starts the data section.
 543 */
 544#ifdef CONFIG_X86_PAE
 545__PAGE_ALIGNED_DATA
 546        /* Page-aligned for the benefit of paravirt? */
 547        .align PGD_ALIGN
 548SYM_DATA_START(initial_page_table)
 549        .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0     /* low identity map */
 550# if KPMDS == 3
 551        .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 552        .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
 553        .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x2000),0
 554# elif KPMDS == 2
 555        .long   0,0
 556        .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 557        .long   pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
 558# elif KPMDS == 1
 559        .long   0,0
 560        .long   0,0
 561        .long   pa(initial_pg_pmd+PGD_IDENT_ATTR),0
 562# else
 563#  error "Kernel PMDs should be 1, 2 or 3"
 564# endif
 565        .align PAGE_SIZE                /* needs to be page-sized too */
 566
 567#ifdef CONFIG_PAGE_TABLE_ISOLATION
 568        /*
 569         * PTI needs another page so sync_initial_pagetable() works correctly
 570         * and does not scribble over the data which is placed behind the
 571         * actual initial_page_table. See clone_pgd_range().
 572         */
 573        .fill 1024, 4, 0
 574#endif
 575
 576SYM_DATA_END(initial_page_table)
 577#endif
 578
 579.data
 580.balign 4
 581/*
 582 * The SIZEOF_PTREGS gap is a convention which helps the in-kernel unwinder
 583 * reliably detect the end of the stack.
 584 */
 585SYM_DATA(initial_stack,
 586                .long init_thread_union + THREAD_SIZE -
 587                SIZEOF_PTREGS - TOP_OF_KERNEL_STACK_PADDING)
 588
 589__INITRODATA
 590int_msg:
 591        .asciz "Unknown interrupt or fault at: %p %p %p\n"
 592
 593#include "../../x86/xen/xen-head.S"
 594
 595/*
 596 * The IDT and GDT 'descriptors' are a strange 48-bit object
 597 * only used by the lidt and lgdt instructions. They are not
 598 * like usual segment descriptors - they consist of a 16-bit
 599 * segment size, and 32-bit linear address value:
 600 */
 601
 602        .data
 603        ALIGN
 604# early boot GDT descriptor (must use 1:1 address mapping)
 605        .word 0                         # 32 bit align gdt_desc.address
 606SYM_DATA_START_LOCAL(boot_gdt_descr)
 607        .word __BOOT_DS+7
 608        .long boot_gdt - __PAGE_OFFSET
 609SYM_DATA_END(boot_gdt_descr)
 610
 611# boot GDT descriptor (later on used by CPU#0):
 612        .word 0                         # 32 bit align gdt_desc.address
 613SYM_DATA_START(early_gdt_descr)
 614        .word GDT_ENTRIES*8-1
 615        .long gdt_page                  /* Overwritten for secondary CPUs */
 616SYM_DATA_END(early_gdt_descr)
 617
 618/*
 619 * The boot_gdt must mirror the equivalent in setup.S and is
 620 * used only for booting.
 621 */
 622        .align L1_CACHE_BYTES
 623SYM_DATA_START(boot_gdt)
 624        .fill GDT_ENTRY_BOOT_CS,8,0
 625        .quad 0x00cf9a000000ffff        /* kernel 4GB code at 0x00000000 */
 626        .quad 0x00cf92000000ffff        /* kernel 4GB data at 0x00000000 */
 627SYM_DATA_END(boot_gdt)
 628