LXR linux/arch/x86/um/vdso/vdso-layout.lds.S

   1/* SPDX-License-Identifier: GPL-2.0 */
   2/*
   3 * Linker script for vDSO.  This is an ELF shared object prelinked to
   4 * its virtual address, and with only one read-only segment.
   5 * This script controls its layout.
   6 */
   7
   8SECTIONS
   9{
  10        . = VDSO_PRELINK + SIZEOF_HEADERS;
  11
  12        .hash           : { *(.hash) }                  :text
  13        .gnu.hash       : { *(.gnu.hash) }
  14        .dynsym         : { *(.dynsym) }
  15        .dynstr         : { *(.dynstr) }
  16        .gnu.version    : { *(.gnu.version) }
  17        .gnu.version_d  : { *(.gnu.version_d) }
  18        .gnu.version_r  : { *(.gnu.version_r) }
  19
  20        .note           : { *(.note.*) }                :text   :note
  21
  22        .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  23        .eh_frame       : { KEEP (*(.eh_frame)) }       :text
  24
  25        .dynamic        : { *(.dynamic) }               :text   :dynamic
  26
  27        .rodata         : { *(.rodata*) }               :text
  28        .data           : {
  29              *(.data*)
  30              *(.sdata*)
  31              *(.got.plt) *(.got)
  32              *(.gnu.linkonce.d.*)
  33              *(.bss*)
  34              *(.dynbss*)
  35              *(.gnu.linkonce.b.*)
  36        }
  37
  38        .altinstructions        : { *(.altinstructions) }
  39        .altinstr_replacement   : { *(.altinstr_replacement) }
  40
  41        /*
  42         * Align the actual code well away from the non-instruction data.
  43         * This is the best thing for the I-cache.
  44         */
  45        . = ALIGN(0x100);
  46
  47        .text           : { *(.text*) }                 :text   =0x90909090
  48}
  49
  50/*
  51 * Very old versions of ld do not recognize this name token; use the constant.
  52 */
  53#define PT_GNU_EH_FRAME 0x6474e550
  54
  55/*
  56 * We must supply the ELF program headers explicitly to get just one
  57 * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  58 */
  59PHDRS
  60{
  61        text            PT_LOAD         FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
  62        dynamic         PT_DYNAMIC      FLAGS(4);               /* PF_R */
  63        note            PT_NOTE         FLAGS(4);               /* PF_R */
  64        eh_frame_hdr    PT_GNU_EH_FRAME;
  65}
  66