qemu/qemu.nsi
<<
>>
Prefs
   1;!/usr/bin/makensis
   2
   3; This NSIS script creates an installer for QEMU on Windows.
   4
   5; Copyright (C) 2006-2012 Stefan Weil
   6;
   7; This program is free software: you can redistribute it and/or modify
   8; it under the terms of the GNU General Public License as published by
   9; the Free Software Foundation, either version 2 of the License, or
  10; (at your option) version 3 or any later version.
  11;
  12; This program is distributed in the hope that it will be useful,
  13; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15; GNU General Public License for more details.
  16;
  17; You should have received a copy of the GNU General Public License
  18; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20; NSIS_WIN32_MAKENSIS
  21
  22!define PRODUCT "QEMU"
  23!define URL     "http://www.qemu-project.org/"
  24
  25!define UNINST_EXE "$INSTDIR\qemu-uninstall.exe"
  26!define UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT}"
  27
  28!ifndef BINDIR
  29!define BINDIR nsis.tmp
  30!endif
  31!ifndef SRCDIR
  32!define SRCDIR .
  33!endif
  34!ifndef OUTFILE
  35!define OUTFILE "qemu-setup.exe"
  36!endif
  37
  38; Optionally install documentation.
  39!ifndef CONFIG_DOCUMENTATION
  40!define CONFIG_DOCUMENTATION
  41!endif
  42
  43; Use maximum compression.
  44SetCompressor /SOLID lzma
  45
  46!include "MUI2.nsh"
  47
  48; The name of the installer.
  49Name "QEMU"
  50
  51; The file to write
  52OutFile "${OUTFILE}"
  53
  54; The default installation directory.
  55!ifdef W64
  56InstallDir $PROGRAMFILES64\qemu
  57!else
  58InstallDir $PROGRAMFILES\qemu
  59!endif
  60
  61; Registry key to check for directory (so if you install again, it will
  62; overwrite the old one automatically)
  63!ifdef W64
  64InstallDirRegKey HKLM "Software\qemu64" "Install_Dir"
  65!else
  66InstallDirRegKey HKLM "Software\qemu32" "Install_Dir"
  67!endif
  68
  69; Request administrator privileges for Windows Vista.
  70RequestExecutionLevel admin
  71
  72;--------------------------------
  73; Interface Settings.
  74;!define MUI_HEADERIMAGE "qemu-nsis.bmp"
  75; !define MUI_SPECIALBITMAP "qemu.bmp"
  76!define MUI_ICON "${SRCDIR}\pc-bios\qemu-nsis.ico"
  77!define MUI_UNICON "${SRCDIR}\pc-bios\qemu-nsis.ico"
  78!define MUI_WELCOMEFINISHPAGE_BITMAP "${SRCDIR}\pc-bios\qemu-nsis.bmp"
  79; !define MUI_HEADERIMAGE_BITMAP "qemu-install.bmp"
  80; !define MUI_HEADERIMAGE_UNBITMAP "qemu-uninstall.bmp"
  81; !define MUI_COMPONENTSPAGE_SMALLDESC
  82; !define MUI_WELCOMEPAGE_TEXT "Insert text here.$\r$\n$\r$\n$\r$\n$_CLICK"
  83
  84;--------------------------------
  85; Pages.
  86
  87!insertmacro MUI_PAGE_WELCOME
  88!insertmacro MUI_PAGE_LICENSE "${SRCDIR}\COPYING"
  89!insertmacro MUI_PAGE_COMPONENTS
  90!insertmacro MUI_PAGE_DIRECTORY
  91!insertmacro MUI_PAGE_INSTFILES
  92!define MUI_FINISHPAGE_LINK "Visit the QEMU Wiki online!"
  93!define MUI_FINISHPAGE_LINK_LOCATION "${URL}"
  94!insertmacro MUI_PAGE_FINISH
  95
  96!insertmacro MUI_UNPAGE_CONFIRM
  97!insertmacro MUI_UNPAGE_INSTFILES
  98
  99;--------------------------------
 100; Languages.
 101
 102!insertmacro MUI_LANGUAGE "English"
 103!insertmacro MUI_LANGUAGE "French"
 104!insertmacro MUI_LANGUAGE "German"
 105
 106;--------------------------------
 107
 108; The stuff to install.
 109Section "${PRODUCT} (required)"
 110
 111    SectionIn RO
 112
 113    ; Set output path to the installation directory.
 114    SetOutPath "$INSTDIR"
 115
 116    File "${SRCDIR}\Changelog"
 117    File "${SRCDIR}\COPYING"
 118    File "${SRCDIR}\COPYING.LIB"
 119    File "${SRCDIR}\README"
 120    File "${SRCDIR}\VERSION"
 121
 122    File "${BINDIR}\*.bmp"
 123    File "${BINDIR}\*.bin"
 124    File "${BINDIR}\*.dtb"
 125    File "${BINDIR}\*.rom"
 126    File "${BINDIR}\openbios-*"
 127
 128    File /r "${BINDIR}\keymaps"
 129!ifdef CONFIG_GTK
 130    File /r "${BINDIR}\share"
 131!endif
 132
 133!ifdef W64
 134    SetRegView 64
 135!endif
 136
 137    ; Write the installation path into the registry
 138    WriteRegStr HKLM SOFTWARE\${PRODUCT} "Install_Dir" "$INSTDIR"
 139
 140    ; Write the uninstall keys for Windows
 141    WriteRegStr HKLM "${UNINST_KEY}" "DisplayName" "QEMU"
 142!ifdef DISPLAYVERSION
 143    WriteRegStr HKLM "${UNINST_KEY}" "DisplayVersion" "${DISPLAYVERSION}"
 144!endif
 145    WriteRegStr HKLM "${UNINST_KEY}" "UninstallString" '"${UNINST_EXE}"'
 146    WriteRegDWORD HKLM "${UNINST_KEY}" "NoModify" 1
 147    WriteRegDWORD HKLM "${UNINST_KEY}" "NoRepair" 1
 148    WriteUninstaller "qemu-uninstall.exe"
 149SectionEnd
 150
 151Section "Tools" SectionTools
 152    SetOutPath "$INSTDIR"
 153    File "${BINDIR}\qemu-img.exe"
 154    File "${BINDIR}\qemu-io.exe"
 155SectionEnd
 156
 157SectionGroup "System Emulations" SectionSystem
 158
 159!include "${BINDIR}\system-emulations.nsh"
 160
 161SectionGroupEnd
 162
 163!ifdef DLLDIR
 164Section "Libraries (DLL)" SectionDll
 165    SetOutPath "$INSTDIR"
 166    File "${DLLDIR}\*.dll"
 167SectionEnd
 168!endif
 169
 170!ifdef CONFIG_DOCUMENTATION
 171Section "Documentation" SectionDoc
 172    SetOutPath "$INSTDIR"
 173    File "${BINDIR}\qemu-doc.html"
 174    File "${BINDIR}\qemu-tech.html"
 175    CreateDirectory "$SMPROGRAMS\${PRODUCT}"
 176    CreateShortCut "$SMPROGRAMS\${PRODUCT}\User Documentation.lnk" "$INSTDIR\qemu-doc.html" "" "$INSTDIR\qemu-doc.html" 0
 177    CreateShortCut "$SMPROGRAMS\${PRODUCT}\Technical Documentation.lnk" "$INSTDIR\qemu-tech.html" "" "$INSTDIR\qemu-tech.html" 0
 178SectionEnd
 179!endif
 180
 181; Optional section (can be disabled by the user)
 182Section "Start Menu Shortcuts" SectionMenu
 183    CreateDirectory "$SMPROGRAMS\${PRODUCT}"
 184    CreateShortCut "$SMPROGRAMS\${PRODUCT}\Uninstall.lnk" "${UNINST_EXE}" "" "${UNINST_EXE}" 0
 185SectionEnd
 186
 187;--------------------------------
 188
 189; Uninstaller
 190
 191Section "Uninstall"
 192    ; Remove registry keys
 193!ifdef W64
 194    SetRegView 64
 195!endif
 196    DeleteRegKey HKLM "${UNINST_KEY}"
 197    DeleteRegKey HKLM SOFTWARE\${PRODUCT}
 198
 199    ; Remove shortcuts, if any
 200    Delete "$SMPROGRAMS\${PRODUCT}\User Documentation.lnk"
 201    Delete "$SMPROGRAMS\${PRODUCT}\Technical Documentation.lnk"
 202    Delete "$SMPROGRAMS\${PRODUCT}\Uninstall.lnk"
 203    RMDir "$SMPROGRAMS\${PRODUCT}"
 204
 205    ; Remove files and directories used
 206    Delete "$INSTDIR\Changelog"
 207    Delete "$INSTDIR\COPYING"
 208    Delete "$INSTDIR\COPYING.LIB"
 209    Delete "$INSTDIR\README"
 210    Delete "$INSTDIR\VERSION"
 211    Delete "$INSTDIR\*.bmp"
 212    Delete "$INSTDIR\*.bin"
 213    Delete "$INSTDIR\*.dll"
 214    Delete "$INSTDIR\*.dtb"
 215    Delete "$INSTDIR\*.rom"
 216    Delete "$INSTDIR\openbios-*"
 217    Delete "$INSTDIR\qemu-img.exe"
 218    Delete "$INSTDIR\qemu-io.exe"
 219    Delete "$INSTDIR\qemu.exe"
 220    Delete "$INSTDIR\qemu-system-*.exe"
 221    Delete "$INSTDIR\qemu-doc.html"
 222    Delete "$INSTDIR\qemu-tech.html"
 223    RMDir /r "$INSTDIR\keymaps"
 224    RMDir /r "$INSTDIR\share"
 225    ; Remove generated files
 226    Delete "$INSTDIR\stderr.txt"
 227    Delete "$INSTDIR\stdout.txt"
 228    ; Remove uninstaller
 229    Delete "${UNINST_EXE}"
 230    RMDir "$INSTDIR"
 231SectionEnd
 232
 233;--------------------------------
 234
 235; Descriptions (mouse-over).
 236!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 237    !insertmacro MUI_DESCRIPTION_TEXT ${SectionSystem}  "System emulation."
 238    !insertmacro MUI_DESCRIPTION_TEXT ${Section_alpha}  "Alpha system emulation."
 239    !insertmacro MUI_DESCRIPTION_TEXT ${Section_alphaw} "Alpha system emulation (GUI)."
 240    !insertmacro MUI_DESCRIPTION_TEXT ${Section_i386}   "PC i386 system emulation."
 241    !insertmacro MUI_DESCRIPTION_TEXT ${Section_i386w}  "PC i386 system emulation (GUI)."
 242    !insertmacro MUI_DESCRIPTION_TEXT ${SectionTools} "Tools."
 243!ifdef DLLDIR
 244    !insertmacro MUI_DESCRIPTION_TEXT ${SectionDll}   "Runtime Libraries (DLL)."
 245!endif
 246!ifdef CONFIG_DOCUMENTATION
 247    !insertmacro MUI_DESCRIPTION_TEXT ${SectionDoc}   "Documentation."
 248!endif
 249    !insertmacro MUI_DESCRIPTION_TEXT ${SectionMenu}  "Menu entries."
 250!insertmacro MUI_FUNCTION_DESCRIPTION_END
 251
 252;--------------------------------
 253; Functions.
 254
 255Function .onInit
 256    !insertmacro MUI_LANGDLL_DISPLAY
 257FunctionEnd
 258