LXR qemu/chardev/meson.build

   1chardev_ss.add(files(
   2  'char-fe.c',
   3  'char-file.c',
   4  'char-io.c',
   5  'char-mux.c',
   6  'char-null.c',
   7  'char-pipe.c',
   8  'char-ringbuf.c',
   9  'char-serial.c',
  10  'char-socket.c',
  11  'char-stdio.c',
  12  'char-udp.c',
  13  'char.c',
  14))
  15chardev_ss.add(when: 'CONFIG_POSIX', if_true: files(
  16  'char-fd.c',
  17  'char-parallel.c',
  18  'char-pty.c',
  19))
  20chardev_ss.add(when: 'CONFIG_WIN32', if_true: files(
  21  'char-console.c',
  22  'char-win-stdio.c',
  23  'char-win.c',
  24))
  25
  26chardev_ss = chardev_ss.apply(config_host, strict: false)
  27
  28softmmu_ss.add(files('msmouse.c', 'wctablet.c', 'testdev.c'))
  29
  30chardev_modules = {}
  31
  32if brlapi.found()
  33  module_ss = ss.source_set()
  34  module_ss.add(when: [brlapi], if_true: [files('baum.c'), pixman])
  35  chardev_modules += { 'baum': module_ss }
  36endif
  37
  38if spice.found()
  39  module_ss = ss.source_set()
  40  module_ss.add(when: [spice], if_true: files('spice.c'))
  41  chardev_modules += { 'spice': module_ss }
  42endif
  43
  44modules += { 'chardev': chardev_modules }
  45