LXR uboot/board/pcippc2/u-boot.lds

   1/*
   2 * (C) Copyright 2001
   3 * Josh Huber <huber@mclx.com>, Mission Critical Linux, Inc.
   4 *
   5 * (C) Copyright 2002
   6 * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   7 *
   8 * See file CREDITS for list of people who contributed to this
   9 * project.
  10 *
  11 * This program is free software; you can redistribute it and/or
  12 * modify it under the terms of the GNU General Public License as
  13 * published by the Free Software Foundation; either version 2 of
  14 * the License, or (at your option) any later version.
  15 *
  16 * This program is distributed in the hope that it will be useful,
  17 * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 * GNU General Public License for more details.
  20 *
  21 * You should have received a copy of the GNU General Public License
  22 * along with this program; if not, write to the Free Software
  23 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24 * MA 02111-1307 USA
  25 */
  26
  27/*
  28 * u-boot.lds - linker script for U-Boot on the Galileo Eval Board.
  29 */
  30
  31OUTPUT_ARCH(powerpc)
  32/* Do we need any of these for elf?
  33   __DYNAMIC = 0;    */
  34SECTIONS
  35{
  36  /* Read-only sections, merged into text segment: */
  37  . = + SIZEOF_HEADERS;
  38  .interp : { *(.interp) }
  39  .hash          : { *(.hash)           }
  40  .dynsym        : { *(.dynsym)         }
  41  .dynstr        : { *(.dynstr)         }
  42  .rel.text      : { *(.rel.text)               }
  43  .rela.text     : { *(.rela.text)      }
  44  .rel.data      : { *(.rel.data)               }
  45  .rela.data     : { *(.rela.data)      }
  46  .rel.rodata    : { *(.rel.rodata)     }
  47  .rela.rodata   : { *(.rela.rodata)    }
  48  .rel.got       : { *(.rel.got)                }
  49  .rela.got      : { *(.rela.got)               }
  50  .rel.ctors     : { *(.rel.ctors)      }
  51  .rela.ctors    : { *(.rela.ctors)     }
  52  .rel.dtors     : { *(.rel.dtors)      }
  53  .rela.dtors    : { *(.rela.dtors)     }
  54  .rel.bss       : { *(.rel.bss)                }
  55  .rela.bss      : { *(.rela.bss)               }
  56  .rel.plt       : { *(.rel.plt)                }
  57  .rela.plt      : { *(.rela.plt)               }
  58  .init          : { *(.init)   }
  59  .plt : { *(.plt) }
  60  .text      :
  61  {
  62    cpu/74xx_7xx/start.o        (.text)
  63
  64/* store the environment in a seperate sector in the boot flash */
  65/*    . = env_offset; */
  66/*    common/env_embedded.o(.text) */
  67
  68    *(.text)
  69    *(.fixup)
  70    *(.got1)
  71  }
  72  _etext = .;
  73  PROVIDE (etext = .);
  74  .rodata    :
  75  {
  76    *(.rodata)
  77    *(.rodata1)
  78    *(.rodata.str1.4)
  79    *(.eh_frame)
  80  }
  81  .fini      : { *(.fini)    } =0
  82  .ctors     : { *(.ctors)   }
  83  .dtors     : { *(.dtors)   }
  84
  85  /* Read-write section, merged into data segment: */
  86  . = (. + 0x00FF) & 0xFFFFFF00;
  87  _erotext = .;
  88  PROVIDE (erotext = .);
  89  .reloc   :
  90  {
  91    *(.got)
  92    _GOT2_TABLE_ = .;
  93    *(.got2)
  94    _FIXUP_TABLE_ = .;
  95    *(.fixup)
  96  }
  97  __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  98  __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  99
 100  .data    :
 101  {
 102    *(.data)
 103    *(.data1)
 104    *(.sdata)
 105    *(.sdata2)
 106    *(.dynamic)
 107    CONSTRUCTORS
 108  }
 109  _edata  =  .;
 110  PROVIDE (edata = .);
 111
 112  . = .;
 113  __u_boot_cmd_start = .;
 114  .u_boot_cmd : { *(.u_boot_cmd) }
 115  __u_boot_cmd_end = .;
 116
 117
 118  . = .;
 119  __start___ex_table = .;
 120  __ex_table : { *(__ex_table) }
 121  __stop___ex_table = .;
 122
 123  . = ALIGN(256);
 124  __init_begin = .;
 125  .text.init : { *(.text.init) }
 126  .data.init : { *(.data.init) }
 127  . = ALIGN(256);
 128  __init_end = .;
 129
 130  __bss_start = .;
 131  .bss (NOLOAD)       :
 132  {
 133   *(.sbss) *(.scommon)
 134   *(.dynbss)
 135   *(.bss)
 136   *(COMMON)
 137   . = ALIGN(4);
 138  }
 139  _end = . ;
 140  PROVIDE (end = .);
 141}
 142